Any solution to system of equations?

I need ANY combination of 8 variables which satisfy:

a+b+c+d+e+f+g+h=0
a^2+b^2+c^2+d^2+e^2+f^2+g^2+h^2=1
a*b+b*c+c*d+d*e+e*f+f*g+g*h+a*h>2/3


Ideally these would be numbers having simple closed forms...

If I exchange third restriction with

a*b+b*c+c*d+d*e+e*f+f*g+g*h+a*h=2/3


I get a solution a=b=c=6^(-0.5); e=f=g=-6^(-0.5); d=h=0;

-
Ok, then please show us what you have tried. –  rm -rf Mar 20 '13 at 18:32
@rm-rf I have tried entering those three restrictions into "Free-form input". Before that I figured an answer to a modified version analytically. Actually this question looks so straightforward to me that if I knew how to proceed the thread wouldn't even exist... –  Pranasas Mar 20 '13 at 18:44
$\left(\sqrt{1/8}, 1/2,\sqrt{1/8}, 0, -\sqrt{1/8}, -1/2, -\sqrt{1/8}, 0\right)$ works: the third expression evaluates to $\sqrt{1/2} \gt 2/3$. (This in fact is the maximum possible value it can attain subject to the restrictions.) –  whuber Mar 20 '13 at 19:51

This is a special kind of problem which succumbs to a standard approach.

Analysis

The question can be solved by maximizing $x \mathbb{A} x'$ and checking that this maximum exceeds $2/3$. The restrictions are (1) that $x=(a,b,\ldots,h)$ must have unit square length and (2) be orthogonal to $e_1 = (1,1,\ldots, 1)$, where $A$ is the matrix

$$\left( \begin{array}{cccccccc} 0 & 1 & 0 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 1 & 0 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 1 & 0 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 1 & 0 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 1 & 0 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 1 & 0 \\ 0 & 0 & 0 & 0 & 0 & 0 & 0 & 1 \\ 1 & 0 & 0 & 0 & 0 & 0 & 0 & 0 \end{array} \right)$$

Solution

Because $\mathbb{A}$ is obviously a rotation matrix (it represents a cyclic permutation of the eight basis vectors), $e_1$ (by virtue of its constant coefficients) must be an eigenvector. Seven other complex eigenvectors can be found orthogonal to $e_1$. Their eigenvalues fall into three groups of complex conjugates, representing rotations by primitive multiples of $2\pi/8$, and one real eigenvalue of $-1$, representing a rotation by $\pi$. We seek the smallest rotation among these rotations, because that corresponds to the largest cosine of the angle, which geometrically is what $x\mathbb{A} x'$ is computing.

The eigensystem can be obtained and displayed as

MatrixForm /@ ({e, ev} = Eigensystem[a = RotateRight[#, 1] & /@ IdentityMatrix[8]] // Simplify)


The cosines are the real parts of the eigenvalues e:

Re[e]


$\left\{-\frac{1}{\sqrt{2}},-\frac{1}{\sqrt{2}},\frac{1}{\sqrt{2}},\frac{1}{\sqrt{2}},-1,0,0,1\right\}$

The two largest real parts, $1/\sqrt{2}\approx 0.7071 \gt 2/3$, occur in the third and fourth places. The real parts of either the third or fourth normalized eigenvectors therefore afford values of $x$ where the desired maximum is attained:

x = Normalize @ (Re /@ ev[[3]])


$\left\{\frac{1}{2 \sqrt{2}},0,-\frac{1}{2 \sqrt{2}},-\frac{1}{2},-\frac{1}{2 \sqrt{2}},0,\frac{1}{2 \sqrt{2}},\frac{1}{2}\right\}$

If any of this seems too abstract, let's check all the requirements:

1. Confirm $x$ is orthogonal to $e_1$:

x .ConstantArray[1, 8]


$0$

2. Confirm $x$ has unit squared length:

x . x


$1$

3. Compute $x\mathbb{A} x'$:

x . a . x


$\frac{1}{\sqrt{2}}$

-
Thanks. And you are actually very good at mathematical aspect of this. –  Pranasas Mar 21 '13 at 17:51