How can I check which file is modified in specific directory?

Question

I want to find which files are recently modified in a specific directory. For this purpose, I wrote a function named Test.

The function's argument is DirectoryPath, and it returns file names whose file dates have been modified. In this example the functions runs once every five seconds.

For this purpose I wrote the following code, but it shows all the file names that are in the directory. That means it doesn't check the ModificationDate with lastModified.

Test[directoryPath_] := Module[{taskId,
   fileNames = FileNames["*", SystemDialogInput["Directory"]],
   lastModified,
   result},
  (
   lastModified = Table[{}, {Length[fileNames]}];
   result = Table[{}, {Length[fileNames]}];
   taskId = 
    CreateScheduledTask[
     Table[(With[{
        i = i, 
        modificationDate = 
          Table[FileDate[Part[fileNames, j], "Modification"],
            {j, 1, Length[fileNames]}]
         },
       (If[(Part[lastModified, i] === Part[modificationDate, i]),
         (Part[result, i] =  ""), 
         (Part[lastModified, i] = Part[modificationDate, i];
          Part[result, i] = Part[fileNames, i])])]),
      {i, 1, Length[fileNames]}],
     {OptionValue[ScanRate], \[Infinity]}];
   StartScheduledTask[taskId];
   {taskId, Dynamic[result]}
   )]

Test[SystemDialogInput["Directory"]]

How can I solve this?

Answer 1

Here is a minimally changed version of your program that works:

Test[directoryPath_] :=
 Module[
  {
   fileNames = FileNames["*", directoryPath],
   lastModified,
   taskId,
   booleanValue = {}
   },
  lastModified = Table[{}, {Length[fileNames]}];
  taskId =
   CreateScheduledTask[
    booleanValue =
     Table[
      With[{j = j, 
        modificationDate = FileDate[fileNames[[j]], "Modification"]},
       If[(lastModified[[j]] === modificationDate),
        "",
        lastModified[[j]] = modificationDate;
        fileNames[[j]]
        ]
       ],
      {j, 1, Length[fileNames]}
      ],
    {5, \[Infinity]}
    ];
  StartScheduledTask[taskId];
  (*Output*)
  Dynamic[booleanValue]
  ]

I moved the initialization of lastModified outside the local variable definition section, because you can't define local variable in terms of other local variables. I changed a == into a = and a == into a ===.

I also removed all non-functional ( ) pairs in your code.