Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

If I know two integers $n$ and $m$ and $m < n$, how can I find two different integers $x$ and $y$ that are nearest to $m$, and satisfy Mod[n,x]==Mod[n,y]==0 ?

For example,

f[720,8] ==> {8,9}
f[720,20] ==> {18,20}

If $n$ is small, we can brute force to test whether an integer is a factor of $n$, and find the nearest two of the factors:

twoNear[n_Integer, m_Integer] := Module[{ls, sortls},
  ls = Select[Range[1, n], Mod[n, #] == 0 &];
  sortls = Sort[Transpose[{ls - m, ls}], Abs[#1[[1]]] < Abs[#2[[1]]] &];
  Sort@sortls[[1 ;; 2, 2]]
 ]

twoNear[720,8]
twoNear[720,20]
(*{8, 9}*)
(*{18, 20}*)

but how to deal with problems such as n=20!, m=1*^9 , n=40!,m=1*^20 ?

share|improve this question
    
Shouldn't f[720,8] return {8,8}? Or do you want that $x\ne y$? –  whuber Mar 11 '13 at 22:44
1  
@whuber yes $x\ne y$ thanks for pointing it out –  user0501 Mar 11 '13 at 22:54
1  
Note that this is a knapsack problem (and NP-Hard), so there will be a limit on what can be achieved. Think of $n$ as giving you a bag of objects; there will be $e_i$ objects with values $\log(p_i)$ when $p_i^{e_i}$ is a term in the prime power factorization of $n$. You want to solve two problems: (1) find subsets of objects whose total values are as large as possible, subject to not exceeding $\log(m)$; and (2) find subsets whose totals are as small as possible, subject to not being less than $\log(m)$. You actually need the best and second-best solutions of both. –  whuber Mar 11 '13 at 23:17
add comment

2 Answers

up vote 7 down vote accepted

My lucky day (night). I get to take my own answer which was of dubious value here and basically repurpose it to give a good response to this question.

We set this up as a mixed linear program by trying to get sums of logs of factors as close to m as possible, subject to coefficients being nonnegative integers that do not exceed the powers of the corresponding factors. There is an added complication in that we need not just the optimal value but also the next best.

So here we go.

nearDivisors[n_, m_] := Module[
  {fax = FactorInteger[n], prec, logs, maxes, len, c, coeffs, c1, c2, 
   c3, diff, epsilon, constraints, vars, min, vals, res1, res2, res3, 
   newproblems, equalities, best},
  prec = Max[20, Log[10., m]];
  logs = Log[N[fax[[All, 1]], prec]];
  maxes = fax[[All, 2]];
  len = Length[fax];
  coeffs = Array[c, len];
  c1 = Table[0 <= c[j] <= maxes[[j]], {j, len}];
  diff = coeffs.logs - Log[m];
  c2 = {diff <= epsilon, -diff <= epsilon};
  c3 = Element[coeffs, Integers];
  constraints = Join[c1, c2, {c3}];
  vars = Join[coeffs, {epsilon}];
  {min, vals} = FindMinimum[{epsilon, constraints}, vars];
  res1 = Round[Exp[coeffs.logs /. vals]];
  vals = coeffs /. vals;
  newproblems = Flatten[Table[
     equalities = Table[c[k] == vals[[k]], {k, j - 1}];
     {Join[constraints, equalities, {c[j] <= vals[[j]] - 1}],
      Join[constraints, equalities, {c[j] >= vals[[j]] + 1}]}
     , {j, len}], 1];
  best = Infinity;
  Do[min = 
    Quiet[FindMinimum[{epsilon, newproblems[[j]]}, vars, 
      WorkingPrecision -> prec]];
   If[Head[min] =!= FindMinimum,
    If[min[[1]] < best,
     best = min[[1]];
     res2 = Round[Exp[coeffs.logs /. min[[2]]]];
     ]
    ], {j, Length[newproblems]}];
  {res1, res2}
  ]

Here are the now-standard benchmark tests. We also check that we used adequate precision so that we can accurately recover the results.

Timing[ndsmall = nearDivisors[20!, 10^9]]

(* Out[967]= {1.840000, {999949860, 1000194048}} *)

20!/ndsmall

(* Out[968]= {2433024000, 2432430000} *)

Timing[ndmiddle = nearDivisors[30!, 10^9]]

(* Out[971]= {20.350000, {999949860, 1000065000}} *)

30!/ndmiddle

(* Out[972]= {265266160257466368000000, 265235619496923758592000} *)

Now we get ambitious.

Timing[ndbig = nearDivisors[40!, 10^20]]

(* Out[969]= {41.020000, {99999622686575390625, 100000079233442099712}} *)

40!/ndbig

(* Out[970]= {8159183618174107243291607040, 8159146367706464256000000000} *)

--- edit ---

Okay, why not...

Timing[ndbigger = nearDivisors[80!, 10^20]]
(* Out[1017]= {2070.830000, {100000004179992913920, 
  100000028588579559040}} *)

80!/ndbigger

(* Out[1018]= \
{715694540546656942785553897344003751254098684983349359903188074751331\
095778689024000000000000000000, \
7156943658557848407002572034351080637013939631522009525004233001820750\
27228721152000000000000000000} *)

--- end edit ---

share|improve this answer
    
I'm glad my question was useful! –  s0rce Mar 12 '13 at 1:57
    
Thanks for the answer, that's cool! –  user0501 Mar 12 '13 at 21:24
    
@sOrce Knapsack questions are always interesting. But reusing an answer just a few minutes later, that's a rare thing. –  Daniel Lichtblau Mar 12 '13 at 21:29
add comment

Brute-forcing for "small" n:

 nrstDvsrsF = Nearest[Divisors[#1], #2, 2] &
 nrstDvsrsF[720, 8]
 (* {8, 9} *)
 nrstDvsrsF[720, 20]
 (* {20, 18} *)
 AbsoluteTiming[nrstDvsrsF[20!, 1*^9]]
 (* {0.031003, {999949860, 1000194048}} *)
 AbsoluteTiming[nrstDvsrsF[30!, 1*^9]]
 (* {14.320432, {999949860, 1000065000}} *)

Warning: As noted by @whuber in comments, do not try this with n=40!,m=1*^20.

share|improve this answer
    
And what happens to RAM usage and computing time when you try the last example in the question? :-) (Actually, that one is barely manageable--why not increase the $40!$ to $80!$, though...) –  whuber Mar 11 '13 at 22:53
    
@whuber @ kguler I can't get an answer for the example n=40!,m=1*^20 before my disk is full, so I have quit the job. –  user0501 Mar 11 '13 at 22:56
    
@whuber, still waiting to see - with fingers crossed that I will not have to restart Windows :) –  kguler Mar 11 '13 at 22:56
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.