Solving and plotting ODEs while varying one of the initial conditions

Question

How can I vary an initial condition in the numerical solution of a system of ODEs and then make a 3D plot of the solution space with that condition as one of the variables.

sol = NDSolve[
  {y''[t] + y'[t] + 4*y[t] + x[t] - x'[t] == 0, 
   x'[t] + 3*c*y[t] == 0,
   y[1] == 1, y'[1] == 1, 
   x[0] == 1}, {x, y}, {t, 0, 10}]

I want to vary one of the condition variables, say y[1] over u = Range[-10, 10, step]. Then I want to make a 3D plot of the solution space (x[t[, y[t], y[1][u]).

Can anyone please guide me in solving this query.

Answer 1

Playing with @ruebenko's suggestion,

c = 1
pf = ParametricNDSolveValue[
  {y''[t] + y'[t] + 4*y[t] + x[t] - x'[t] == 0,
   x'[t] + 3*c*y[t] == 0, y[1] == 1,
   y'[1] == u,
   x[0] == 1}, y, {t, 0, 10}, {u \[Element] Reals}]

Plot3D[pf[u][t], {u, -10, 10}, {t, 0, 10}, PlotRange -> All]

Answer 2

ruebenko has pointed out the best way to solve this in the comment above: use ParametricNDSolve in version 9. Then, I'd like to post my clumsy solution with version 8 since I've already finished it…:

c = 1;
zmin = -1; zmax = 1; n = 25;
tmin = -1; tmax = 1;
ex = 
 Table[Join[{z}, #] & /@ 
       Transpose[{First[(x /. First@#)["Coordinates"]], (x /. First@#)["ValuesOnGrid"]}] &@
       NDSolve[{y''[t] + y'[t] + 4 y[t] + x[t] - x'[t] == 0, 
                x'[t] + 3 c y[t] == 0, y[1] == z, y'[1] == 1, x[0] == 1}, 
               {x, y}, {t, tmin, tmax}], 
       {z, zmin, zmax, (zmax - zmin)/n}];

ListPlot3D[Flatten[ex, 1]]

Just for your sample, it can be solved analytically, too:

c = 1;
sol = DSolve[{y''[t] + y'[t] + 4 y[t] + x[t] - x'[t] == 0, 
              x'[t] + 3 c y[t] == 0, y[1] == z, y'[1] == 1, x[0] == 1}, 
             {x, y}, {t}];
Plot3D[x[t] /. sol, {z, -1, 1}, {t, -1, 1}]