Piecewise linear Interpolation between data points

Question

Is there some sort of functionality built into Mathematica that will let me linearly interpolate between (x, y) pairs of data in an array?

Example: I have the two points (1, 10) and (2, 20), how can I find out what the interpolant at 1.5 would be?

Answer 1

What about using Interpolation?

f = Interpolation[{{1, 10}, {2, 20}}, InterpolationOrder -> 1]
f[1.5]

Answer 2

Although not as elegant as halirutan's post, this helps alternatively,

f:=Rescale[#,{1,2},{10,20}]&; 
f[1.5]

Answer 3

Not as elegant as above approaches, but Fit can also be used. To try different shape functions:

data = {{1, 10}, {2, 20}};
trial = {{1, x}, {1, x, x^2}, {1, x, x^2, x^3}, {1, Sin[x]}, {1, Cos[x]}, 
         {1, Sin[x], Cos[x]}, {1, x, Exp[x]}, {1, x, x^2, Exp[x]}};
fits = Fit[data, #, x] & /@ trial;
x0 = 1.5;
Grid[Partition[
  Plot[#, {x, 0, 3}, Frame -> True, ImageSize -> 230, 
     FrameLabel -> {{None, None}, {None, 
        Grid[{{"f(x)=", #, SpanFromLeft}, {"f(", x0,")=", # /. x -> x0}}, 
            Spacings -> 0]}}, 
     Epilog -> {Red, PointSize[.1], Point[{x0, # /. x -> x0}]}, 
     ImagePadding -> {{30, 30}, {5, 50}}] & /@ fits, 3], Frame -> All]

Answer 4

Apparently, it has been missed that InterpolatingPolynomial[] can be used for "lerping". Here's halirutan's example as a one-liner:

InterpolatingPolynomial[{{1, 10}, {2, 20}}, 1.5]
   15.