Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

$l_{2}$ and $\theta$ are the variables. All other parameters are constants. I need to find $l_{2}$ and $\theta$ in terms of these constants.

$\frac{\mu_{0}\sin(\theta-\theta_{0})}{\sqrt{l_{2}^2 +\beta_{0}l_{2}+\mu_{0}l_{2}\cos(\theta-\theta_{0}) +\lambda_{0}}} + \frac{\mu_{1}\sin(\theta-\theta_{1})}{\sqrt{l_{2}^2 +\beta_{1}l_{2}+\mu_{1}l_{2}\cos(\theta-\theta_{1}) +\lambda_{1}}} =0 $

and

$\frac{2l_{2}+\beta_{0}+\mu_{0}\cos(\theta-\theta_{0})}{\sqrt{l_{2}^2 +\beta_{0}l_{2}+\mu_{0}l_{2}\cos(\theta-\theta_{0}) +\lambda_{0}}}+ \frac{2l_{2}+\beta_{1}+\mu_{1}\cos(\theta-\theta_{1})}{\sqrt{l_{2}^2 +\beta_{1}l_{2}+\mu_{1}l_{2}\cos(\theta-\theta_{1}) +\lambda_{1}}} =\frac{-2}{1+Vr^{l_{2}/D}}$

Here's the Mathematica code I used:

Solve[{(μ0 Sin[t - t0])/Sqrt[ l2^2 + β0 l2 +μ0 l2 Cos[t - t0] + λ0] + 
    (μ1 Sin[t - t1])/ Sqrt[l2^2 + β1 l2 + μ1 l2 Cos[t - t1] + λ1] ==  0, 
    (2 l2 + β0 + μ0 Cos[t - t0])/Sqrt[ l2^2 + β0 l2 + μ0 l2 Cos[t - t0] + λ0] + 
    ( 2 l2 + β1 + μ1 Cos[t - t1])/Sqrt[  l2^2 + β1 l2 + μ1 l2 Cos[t - t1] + λ1] + 
    2/( 1 + V r^(l2/D0)) == 0}, {t, l2}]

This didn't work.

How can I use Mathematica techniques to solve this equation?

share|improve this question
1  
As posed this is not a question -- it's just a complaint. What kind of answer are you look for? –  m_goldberg Mar 5 '13 at 3:19
    
@m_goldberg how do I solve that? –  Norman Mar 5 '13 at 4:02
    
In spirit this is the same question as mathematica.stackexchange.com/questions/20606/…. It suffers from exactly the same problem: you cannot hope to find a closed symbolic solution to an equation in which the unknown(s) appear as exponents (as $l_2$ does on the rhs) unless there is some magical cancellation (which there is not here). –  whuber Mar 5 '13 at 4:28
    
when susbtitue values still doesn't work. [Mu]0 = 0; [Mu]1 = -9418; t0 = 0; t1 = 0; [Lambda]0 = 250000; [Lambda]1 = 22629049; [Beta]0 = 0; [Beta]1 = 0; V = 148; r = 1.1; D0 = 3640; –  Norman Mar 5 '13 at 5:33
    
Solve cannot unravel the transcendental dependencies (use of both l2 and r^(l2/D0) will likely cause trouble here). Per documentation "Solve deals primarily with linear and polynomial equations." Use the method Simon Woods shows, or similar, for solving in presence of explicitly numeric parameters. –  Daniel Lichtblau Mar 5 '13 at 14:54
add comment

closed as too localized by m_goldberg, whuber, Yves Klett, Szabolcs, rcollyer Mar 7 '13 at 2:54

This question is unlikely to help any future visitors; it is only relevant to a small geographic area, a specific moment in time, or an extraordinarily narrow situation that is not generally applicable to the worldwide audience of the internet. For help making this question more broadly applicable, visit the help center.If this question can be reworded to fit the rules in the help center, please edit the question.

1 Answer

up vote 3 down vote accepted

Since you have provided numerical values for the constants, you can

  1. Use plotting functions to approximately locate the solutions
  2. Use FindRoot to refine the approximations

First define the numerical constants and the equations:

μ0 = 0; μ1 = -9418; t0 = 0; t1 = 0; λ0 = 250000; \
λ1 = 22629049; β0 = 0; β1 = 0; V = 148; r = 1.1; \
D0 = 3640;

eq = {(μ0 Sin[t - t0])/
      Sqrt[l2^2 + β0 l2 + μ0 l2 Cos[
          t - t0] + λ0] + (μ1 Sin[t - t1])/
      Sqrt[l2^2 + β1 l2 + μ1 l2 Cos[t - t1] + λ1] ==
     0, (2 l2 + β0 + μ0 Cos[t - t0])/
      Sqrt[l2^2 + β0 l2 + μ0 l2 Cos[
          t - t0] + λ0] + (2 l2 + β1 + μ1 Cos[
          t - t1])/
      Sqrt[l2^2 + β1 l2 + μ1 l2 Cos[t - t1] + λ1] + 
     2/(1 + V r^(l2/D0)) == 0};

Using ContourPlot you can visualise the solutions:

With[{eq = eq}, ContourPlot[eq, {t, -7, 7}, {l2, -3000, 3000}]]

enter image description here

It looks like the first equation is satisfied by $t = n \pi$. Let's check:

eq[[1]] /. Sin[t] -> 0
(*  True  *)

The solutions of the second equation occur around $l2 = 2000$ for $cos \theta = 1$ and $l2 = -2000$ for $cos \theta = -1$. We can use FindRoot to refine these estimates:

FindRoot[eq[[2]] /. Cos[t] -> 1, {l2, 2000}]
(*  {l2 -> 1879.45}  *)

FindRoot[eq[[2]] /. Cos[t] -> -1, {l2, -2000}]
(*  {l2 -> -2152.18}  *)

So the solutions are $t=n\pi$ and $l2=1879.45 \text{ for even } n$, $l2=-2152.18\text{ for odd } n$

share|improve this answer
    
if we have another two constraints like below how could I use mathematica to solve the problem l2^2 + [Beta]0 l2 + [Mu]0 l2 Cos[t - t0] + [Lambda]0 >[Mu]4 and l2^2 + [Beta]1 l2 + [Mu]1 l2 Cos[t - t1] + [Lambda]0 >[Mu]5 –  Norman Mar 7 '13 at 10:24
add comment

Not the answer you're looking for? Browse other questions tagged or ask your own question.