Returning a function from a Module [duplicate]

Question

This question already has an answer here:

• What are the use cases for different scoping constructs? 7 answers

I'm having problems working with the output from DSolve whilst in a module. To handle the result outside a module typically I would do something like

 f[t] = y[t] /. solution

But inside a module my t is now t$ followed by some numbers. How can I create and return a function from the output of DSolve inside a module?

---

Here is my code:

Module[{equations,solution,h,t},
  m=1;
  g=9.8;
  equations = {y''[t]== -m g,y'[0]==100,y[0]==0};
  solution = Flatten@ DSolve[equations,y,t];
  h[t] = y[t] /. solution;
  h[1]]

I get h = 100. t$16608-4.9 t$16608^2, but h[1] = h$16909[1).

Answer 1

If I understand you correctly, you can use DSolve[eqs, y, t] instead of DSolve[eqs, y[t], t] to get a rule like y -> Function[ arg, ... ], so the t, whether it's local or not, will not make difference.

Module[{t}, DSolve[y'[t] == t, y, t] ]

{{y -> Function[{t$31879}, t$31879^2/2 + C[1]]}}

y[t] /. %

{t^2/2 + C[1]}

Answer 2

You could return a pure function. Like this

m = 1;
g = 9.8;

h = Module[{equations, solution, t},
      equations = {y''[t] == -m g, y'[0] == 100, y[0] == 0};
      solution = First@Flatten@DSolve[equations, y[t], t];
      With[{x = Last @solution /. t -> #1}, x &]]

100. #1 - 4.9 #1^2 &

 h[1]

95.1