“Stacked” BarChart with BarOrigin $\to$ Top makes y-tick marks negative

Question

When BarChart layout is "Stacked", setting BarOrigin -> Top makes the y-axis tick marks negative. BarChart documentation shows an example - but not "Stacked" - with correct positive y-axis tick marks.

For example,

data = Table[RandomInteger[{1, 10}], {3}, {4}];

BarChart[MapThread[Labeled[#1, #2, Above] &, {data, {1, 2, 3}}], 
 ChartLayout -> "Stacked",
 BarOrigin -> Top, 
 ChartStyle -> 
  Reverse@{Lighter@Blue, Blue, Darker@Blue, Darker@Darker@Blue}, 
 ChartLabels -> {{"a", "b", "c"}, None}, 
 Frame -> {False, True, False, False}, 
 FrameLabel -> {"x axis", "y axis"},
 FrameTicks -> {None, Automatic}, 
 BaseStyle -> {FontFamily -> "Helvetica", FontSize -> 14}]

Gives:

Is there an option to control this behavior without explicitly setting FrameTicks -> {None, Table[{-i, i}, {i, 0, 25, 5}]}, which works but is a hack.

Answer 1

By looking at the InputForm of the graphics in original post, I found a function Charting`FindTicks. It looks like what's needed.

Change FrameTicks -> {None, Automatic} to FrameTicks -> {None, Charting`FindTicks[{-1, 0}, {1, 0}]}:

Answer 2

One possible, although probably not ideal solution is to remove the Frame. Since you are not using most of the Frame anyways this mostly changes where the Labels are put.

data = Table[RandomInteger[{1, 10}], {3}, {4}];

BarChart[MapThread[Labeled[#1, #2, Above] &, {data, {1, 2, 3}}], 
 ChartLayout -> "Stacked", BarOrigin -> Top, 
 ChartStyle -> 
  Reverse@{Lighter@Blue, Blue, Darker@Blue, Darker@Darker@Blue}, 
 ChartLabels -> {{"a", "b", "c"}, None}, Frame -> False, 
 AxesLabel -> {"x axis", "y axis"}, FrameTicks -> {None, Automatic}, 
 BaseStyle -> {FontFamily -> "Helvetica", FontSize -> 14}]

Answer 3

This seems like a bug in BarChart in that the non-negative ticks are not applied to the Frame.
One can fix this by applying the frame afterward and porting the Ticks spec:

BarChart[MapThread[Labeled[#1, #2, Above] &, {data, {1, 2, 3}}], BarOrigin -> Top, 
  ChartLayout -> "Stacked", 
  ChartStyle -> Reverse@{Lighter@Blue, Blue, Darker@Blue, Darker@Darker@Blue}, 
  ChartLabels -> {{"a", "b", "c"}, None}, FrameLabel -> {"x axis", "y axis"}];

Show[%, Frame -> {0, 1, 0, 0}, FrameTicks -> Options[%, Ticks][[1, 2]]]

Examination of the content of that option reveals the Charting`FindTicks function that Silvia posted, which is a more direct way in this case. This answer however may illustrate a way of approaching other such problems which appear from time to time.