How do I get my equation to have the form $(x-a)^2 + (y-b)^2 + (z-c)^2-d = 0$?

Question

I want Mathematica to express the equation $$-11 - 2 x + x^2 - 4 y + y^2 - 6 z + z^2=0$$ in the form $$(x - 1)^2 + (y - 2)^2 + (z - 3)^2 - 25=0$$ How do I tell Mathematica to do that?

Answer 1

You can use custom transformation rules, for example:

-11 - 2 x + x^2 - 4 y + y^2 - 6 z + z^2 //. 
   (a : _ : 1)*s_Symbol^2 + (b : _ : 1)*s_ + rest__ :> 
       a (s + b/(2 a))^2 - b^2/(4 a) + rest

returns

(* -25 + (-1 + x)^2 + (-2 + y)^2 + (-3 + z)^2  *)

The above rule does not account for cases where b is zero, but those are easy to add too, if needed.

Answer 2

SolveAlways[{-11 - 2 x + x^2 - 4 y + y^2 - 6 z +  z^2 ==
 (x - a)^2 + (y - b)^2 + (z - c)^2 - 25}, {x, y, z}]
(*{{a -> 1, b -> 2, c -> 3}}*)

Updated:

eq = (x - a)^2 + (y - b)^2 + (z - c)^2 - d;
sol = SolveAlways[{-11 - 2 x + x^2 - 4 y + y^2 - 6 z + z^2 == eq}, {x, y, z}]
eq /. sol // PolynomialForm[#, TraditionalOrder -> True] &

(* {{d -> 25, a -> 1, b -> 2, c -> 3}} *)
(* {(x-1)^2+(y-2)^2+(z-3)^2-25} *)

Answer 3

An algebraic one:

h = -2 x + x^2 - 4 y + y^2 - 6 z + z^2 == 11;
((# /. {x -> 0, y -> 0, z -> 0}) + h[[2]] == #) &@
 Total[(#2/2/Sqrt@#3 + Sqrt@#3 #4)^2 & @@@ (Join[CoefficientList[h[[1]], #], {#}] & /@ {x, y, z})]

(*
 25 ==(-1 + x)^2 + (-2 + y)^2 + (-3 + z)^2 
*)

Answer 4

What about this: This is your left-hand part:

    expr1 = \[Minus]11 \[Minus] 2 x + x^2 \[Minus] 4 y + 
   y^2 \[Minus] 6 z + z^2;

expr2=expr1 /. {x -> X + 1, y -> Y + 2, z -> Z + 3} // Simplify

The result is

-25 + X^2 + Y^2 + Z^2

Now back to old notations:

expr2 /. {X -> x - 1, Y -> y - 2, Z -> z - 3}

The result is:

-25 + (-1 + x)^2 + (-2 + y)^2 + (-3 + z)^2

Answer 5

A different route:

(* polynomial depression *)
depress[poly_] := depress[poly, First@Variables[poly]]

depress[poly_, x_] /; PolynomialQ[poly, x] := Module[{n = Exponent[poly, x], x0},
        x0 = -Coefficient[poly, x, n - 1]/(n Coefficient[poly, x, n]);
        Normal[Series[poly, {x, x0, n}]]]

tst = -11 - 2 x + x^2 - 4 y + y^2 - 6 z + z^2;

vars = {x, y, z};
{cnst, lin, quad} = MapAt[Diagonal, Normal[CoefficientArrays[tst]], {3}];

cnst + Total[MapThread[depress[#1 FromDigits[{##2}, #1]] &, {vars, quad, lin}]]
   -25 + (-1 + x)^2 + (-2 + y)^2 + (-3 + z)^2