How to automate a FrontEnd return?

Question

I use some custom shortcut keys in KeyEventTranslations.tr. One is for the Delete All Output function:

Item[KeyEvent["w", Modifiers -> {Control}], 
    FrontEnd`FrontEndExecute[FrontEnd`FrontEndToken["DeleteGeneratedCells"]]]

or simply:

Item[KeyEvent["w", Modifiers -> {Control}], "DeleteGeneratedCells"]

This works as expected, putting up the dialog: "Do you really want to delete all the output cells in the notebook?". Is there any way to set up KeyEventTranslations.tr that when I hit Ctrl+w the dialog is automatically acknowledged and I don't have to hit Enter? The same goes for the Quit kernel function, that also puts up a dialog.

Answer 1

Try using this:

FrontEndExecute[
  {FrontEnd`NotebookFind[FrontEnd`SelectedNotebook[], 
                         "Output", All, CellStyle, AutoScroll->False], 
   FrontEnd`FrontEndToken["Clear"]}]

(Untested in KeyEventTranslations.tr, but works as a button!)

---

Regarding automating confirming the dialog---I don't think it is possible from within Mathematica. I'd like to note though that you can press Space to confirm the dialog (instead of using Enter), which is considerably easier for me due to the size and position of the key.

---

Update: As Albert Retey pointed out in a comment, this will only remove output cells, but not "Message" or "Print" cells. Those need to be added separately to the command, and this is still a workaround to finding all GeneratedCells.

Answer 2

This just adds another hack for the Quit without confirm. It's not especially nice and I also haven't tested it in KeyEventTranslations.tr but it works from a Button with Evaluator -> None in versions 6,7 and 8 on Windows:

FrontEnd`FrontEndExecute[{
  FrontEnd`NotebookPut[
   Notebook[{
     Cell["NotebookClose[EvaluationNotebook[]];Quit[];", "Input"]
     },
    "ClosingSaveDialog" -> False,
    WindowSize -> {10, 10},
    WindowMargins -> {{-100, Automatic}, {-100, Automatic}}
    ]
   ],
  FrontEnd`FrontEndToken[FrontEnd`NotebookPutReturnObject[], 
   "EvaluateNotebook"],
  FrontEnd`SetSelectedNotebook[FrontEnd`InputNotebook[]]
  }]

it should be noted that Visible -> False for the Notebook does not work, thus the settings for WindowSize and WindowMargins. The SetSelectedNotebook seems to reset the focus to the button notebook when used from a button, but since none of these functions are documented I don't know how it will behave when used from a keyboard shortcut.