How can I make a plot of the Higgs potential?

I was wondering, how would could I make a drawing of the Higgs potential aka "mexican hat potential". I am quite new to Mathematica and don't know where to look to learn how to implement such a complex function.

-
Plot3D[#^2 - 1.5 # &@(x^2 + y^2), {x, -1, 1}, {y, -1, 1}] –  acl Feb 14 '13 at 2:22

It is probably a common student misconception that it is "such a complex function". In actuality, it is quite simple. You should read: A pedagogical example: the Mexican hat potential. Very roughly you get the Mexican hat from interplay between two power functions: a x^4 and b x^2. If parabola b x^2 is inverted you get a bump in the center of your a x^4 well. Let's see it on simplest algebraic example - define potential:

V[x_, T_] := x^4 + T x^2


Now rotate with RevolutionPlot3D to get a 3D shape out of 2D profile:

Manipulate[

RevolutionPlot3D[V[x, T], {x, 0, 2}, {q, 0, 1.5 Pi},

PlotPoints -> 30,
PlotStyle -> Opacity[.5],
ColorFunction -> "DarkRainbow",
Mesh -> 20,
MeshStyle -> Opacity[.5],
SphericalRegion -> True,
BoxRatios -> {1, 1, .5},
ImageSize -> 400],

{{T, -4, "Symmetry breaking parameter"}, -5, 5, Appearance -> "Labeled"}]


There is a nice Demonstration "The Higgs Particle" by S. M. Blinder. You can often find relevant things at the Demonstrations Project - code can be downloaded. A good start for your homework.

-
I know the Mexican hat as the second derivative of the Gaussian function. See also the MexicanHatWavelet doc page. –  Sjoerd C. de Vries Feb 14 '13 at 6:31
@SjoerdC.deVries General shape has many common functional expressions. In physics of symmetry breaking what I mentioned is the simplest - see A pedagogical example: the Mexican hat potential –  Vitaliy Kaurov Feb 14 '13 at 6:48