Cell output controlled by CellFrameLabel Checkbox?

Question

The following generates a Cell that returns the state of the checkbox when evaluated:

CellPrint[
  ExpressionCell[
    {DynamicModule[{val=True}
      , Checkbox[
          Dynamic[val, (val=#; SetOptions[EvaluationCell[], TaggingRules->{"value"->val}])&]
        ]
      ]
    , Dynamic@CurrentValue[{TaggingRules,"value"}]
    }
  , TaggingRules->{"value"->True}
  , Evaluatable->True
  , CellEvaluationFunction->(CurrentValue[{TaggingRules,"value"}]&)]
]

Moving the checkbox into the frame label breaks the functionality. Why?

CellPrint[
  ExpressionCell[
    Dynamic@CurrentValue[{TaggingRules,"value"}]
  , TaggingRules->{"value"->True}
  , CellFrameLabels->
    {
      {ToBoxes[
        DynamicModule[{val=True}
        , Checkbox[
            Dynamic[val, (val=#; SetOptions[Print[FullForm@EvaluationCell[]];EvaluationCell[], TaggingRules->{"value"->val}])&]
          ]
        ]
      ], None}
    , {None,None}
    }
  , Evaluatable->True
  , CellEvaluationFunction:>(Print[FullForm@EvaluationCell[]];CurrentValue[{TaggingRules,"value"}]&)]
]

Printing the EvaluationCell[] shows that SetOptions is setting the TaggingRules on the FrameLabel cell, not the main cell. How does one update the tagging rules of the main cell from within a frame?

Answer 1

Given that the objective has been clarified as "How does one update the tagging rules of the main cell from within a frame?" here is a solution:

CellPrint[
 ExpressionCell[Dynamic@CurrentValue[{TaggingRules, "value"}],
  CellTags -> {"X"},
  TaggingRules -> {"value" -> True}, 
  CellFrameLabels -> {{ToBoxes[
      DynamicModule[{val = True}, Checkbox[Dynamic[val, (val = #;
           NotebookLocate["X"]; 
           SetOptions[NotebookSelection@EvaluationNotebook[], 
            TaggingRules -> {"value" -> val}]) &]]]], None}, {None, 
     None}},
  Evaluatable -> True]]

checked:

We begin with the checkbox checked and the tagging rules "value" for the cell displayed as True.

unchecked:

We uncheck the checkbox. The tagging rules "value" for the cell is now set to False.

We can toggle the checkbox over and over to confirm that this does exactly what the OP has sought. You can use show expression if in doubt to verify that the tagging rule has changed locally in what the OP calls the "main cell" -- and not at the notebook level.

And you can do other things to monitor events. Here we see that the notebook level tagging rules are not affected but the local cell tagging rules change with the value of the checkbox.

And so on. In summary the tagging rule in the "main cell" has been updated by checking/unchecking a checkbox located in a cell frame.