How do I place vertical GridLines in front of horizontal ones?

Question

By default horizontal GridLines are placed in front of vertical GridLines:

style = Directive[#, AbsoluteThickness[5]] &;
Graphics[Circle[], Frame -> True, ImagePadding -> 1, GridLines -> Automatic, 
    GridLinesStyle -> style /@ #] & /@ {{LightGray, Black}, {Black, LightGray}} // GraphicsRow

How can I place the vertical lines in front so that they appear uninterrupted?

I do not wish to resort to manually drawing Line expressions.

Answer 1

This at least gets the result:

style = Directive[#, AbsoluteThickness[5]] &;
Overlay[
    {Graphics[Circle[], Frame -> True, ImagePadding -> 1,
      GridLines -> Automatic,
      GridLinesStyle -> style /@ {#1, #2}],
     Graphics[Circle[], Frame -> True, ImagePadding -> 1,
      GridLines -> Automatic,
      GridLinesStyle -> style /@ {#1, Opacity[0]}]}] & @@@
  {{LightGray, Black}, {Black, LightGray}} // GraphicsRow

Answer 2

More a workaround rather than a solution, but simple and maybe useful with some pre-planning of data and such:

Rotate[Graphics[Circle[], Frame -> True, ImagePadding -> 1, 
  GridLines -> Automatic, 
  GridLinesStyle -> style /@ {LightGray, Black}], 90 Degree]

Answer 3

This is a possible way by Inset, but I'm still not very sure why it's 2.1:

style = Directive[#, AbsoluteThickness[5]] &;

Graphics[{Opacity[0], Circle[]}, Frame -> True, 
  FrameStyle -> Opacity[0], ImagePadding -> 1, 
  GridLines -> {Automatic, Automatic}, 
  GridLinesStyle -> style /@ {Opacity[0], Black}];

Graphics[Circle[], Frame -> True, ImagePadding -> 1, 
  GridLines -> {Automatic, Automatic}, 
  GridLinesStyle -> style /@ {LightGray, Opacity[0]}];

Show[%%, Epilog -> Inset[%, Center, {0, 0}, {2.1, Automatic}]]

According to the documentation of PlotRangePadding:

PlotRangePadding->Automatic adds a total of 4% for PlotRange settings All, Full, and Automatic.

It should be $2\times (1+4\%)=2.08$, but in fact 2.08 will be worse than 2.1 here. Don't know why...

Answer 4

I guess I'll put on paper a simple fix that works only with the gray/black lines as shown rather than being a general solution. (Desiring a general solution was the reason I originally used the garish colored lines that Yves complained about.)

style = Directive[#, AbsoluteThickness[5]] &;

Graphics[Circle[], Frame -> True, ImagePadding -> 1, GridLines -> Automatic, 
 GridLinesStyle -> style /@ {Black, Opacity[0.3]}]

Plainly this won't work with other combinations (warning: garish colors):

Graphics[Circle[], Frame -> True, ImagePadding -> 1, GridLines -> Automatic, 
 GridLinesStyle -> style /@ {Yellow, {Green, Opacity[0.3]}}]