relative scale of elements in ImageCompose

Question

My code:

sqrSize = 16/2;
dots = Flatten[Table[{2 i + Mod[j, 2], j Sqrt[3]}, 
                     {i, -sqrSize, sqrSize}, {j, -sqrSize, sqrSize}], 1];
inner = Select[dots, Norm[#] <= 5 &];
zePlot = ListPlot[{dots, inner}, PlotRange -> {{-sqrSize, sqrSize}, {-sqrSize, sqrSize}}, 
    AspectRatio -> 1, Axes -> None, PlotStyle -> {{PointSize[0.02]}}, 
    Epilog -> {Circle[{0, 0}, 5], PlotStyle -> {Blue, Opacity[0.2]}}];
ImageCompose[zePlot, {Graphics[{Blue, Disk[{0, 0}, 5]}], 0.2}]

gives this Plot as result:

Two issues:

1. The disk seems to use another scale than the rest of the image; I'd like to have it the same size as the circle
2. (not in the code yet) Instead of the disk I'd like to have its complement, i.e. the area outside the circle should be blue, inside the circle white.

How can I achieve these?

Answer 1

 ImageCompose[zePlot, {Graphics[{Blue, Disk[{0, 0}, 5]}, 
  PlotRange -> {{-sqrSize, sqrSize}, {-sqrSize, sqrSize}}], 0.2}]

  ImageCompose[zePlot, {Graphics[{White, Disk[{0, 0}, 5]}, 
  PlotRange -> {{-sqrSize, sqrSize}, {-sqrSize, sqrSize}}, 
  Background -> Blue], 0.2}]

Answer 2

You can use Show to combine at a Graphics level, as opposed to ImageCompose that in a sense sees the graphics as images and just aligns them on top of each other not knowing about the different scales etc. This is why adding PlotRange to the Graphics fixes it in the ImageCompose case.

Show[zePlot, Graphics[{Opacity[0.2], Blue, Disk[{0, 0}, 5]}]]

Answer 3

I favor ssch's approach of keeping this within the domain of vector graphics which of course are scalable and editable in a way that a raster is not. Your point #2 graphic:

Show[
 zePlot,
 Prolog -> {White, Disk[{0, 0}, 5]},
 Background -> RGBColor[0.8, 0.8, 1]
]

For illustration Prolog can also be used for the point #1 graphic:

Show[zePlot,
  Prolog -> {RGBColor[0.8, 0.8, 1], Disk[{0, 0}, 5]}
]

Answer 4

I thought I would show how this might be done with the Presentations Application (which I sell through my web site).

There I believe the approach is more natural because you simply draw one thing after another. Everything is treated as a graphic primitive and there is no necessity to jump between Graphics levels, or to use Prolog or Epilog.

CirclePoint is just a Presentations shortcut for drawing an outlined disk of a given size in printers points.

Module[
 {sqrSize = 16/2, dotLocations},
 dotLocations = 
  Flatten[Table[{2 i + Mod[j, 2], j Sqrt[3]}, {i, -sqrSize, 
     sqrSize}, {j, -sqrSize, sqrSize}], 1];
 (* Generate the dot graphics *)
 dots = CirclePoint[#, 3.5, Black, If[Norm[#] <= 5,
      ColorData["Legacy"]["DarkSeaGreen"], 
      ColorData["Legacy"]["SandyBrown"]]] & /@ dotLocations;
 Draw2D[
  {(* Draw the outer background *)
   LightBlue,
   RegionDraw[
    Norm[{x, y}] >= 5, {x, -sqrSize, sqrSize}, {y, -sqrSize, sqrSize}],
   (* Draw the dots *)
   dots,
   (* Draw the boundary circle *)
   Black,
   Circle[{0, 0}, 5]},
  PlotRange -> sqrSize,
  Frame -> True, FrameTicks -> False,
  ImageSize -> 300]
 ]