Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Sign up
Here's how it works:
  1. Anybody can ask a question
  2. Anybody can answer
  3. The best answers are voted up and rise to the top

I want to estimate the ratio of integrals:

$$ \frac{\int \frac{4 a T^3}{\frac{4 a T^4}{3}+\Lambda_1 \left(\frac{4}{T^3}+1\right)}}{\int \frac{4 a T^3}{\frac{4 a T^4}{3}+\Lambda_0 \left(\frac{4}{T^3}+1\right)}} $$

where $\Lambda_1$=$\Lambda$ (constant) and $\Lambda_1$=0 for some temperature $T_0$ (arbitrary constants are set to zero).

When I try to integrate the function:

f[T_] := (4 a T^3)/(4/3 a T^4 + Λ (1 + 4/T^3))
Integrate[ f[T], T] 

I get the result like this (with # and &) :

12a RootSum[ 12 Λ + 3 Λ #1^3 + 4 a #1^7 &, (Log[T - #1] #1^4)/(9 Λ + 28 a #1^4) &]

What am I doing wrong? How do I get an explicit expression for the integral? How do I solve this problem ?

share|improve this question
(1) The documentation provides some helpful hints. (2) Typically there are seven discrete poles of the integrand in the Complex plane, so the best you can hope for--except for some special values of $a$ and $\Lambda$--is precisely a sum over those poles, which is what RootSum accomplishes. What, then, would a more "explicit expression" look like? – whuber Jan 22 '13 at 19:24
How can I, at least, approximate this function for $T\rightarrow\infty$? – molkee Jan 22 '13 at 19:51
You can do Series[f[bigT], {bigT, Infinity, 10}]. – b.gatessucks Jan 22 '13 at 19:53
The integral diverges logarithmically at $\infty$, because eventually the $4aT^4/3$ term in the denominator overwhelms the other term, giving an integral proportional to $\int dT/T$. – whuber Jan 22 '13 at 20:14
A comment on the mathematical problem itself: an indefinite integral is defined only up to an arbitrary constant, so for the ratio to be well defined you need additional conditions. – Szabolcs Jan 22 '13 at 20:37
up vote 2 down vote accepted

It would be more appropriate to use this definition :

f[T_, a_, Λ_] := (4 a T^3)/(4/3 a T^4 + Λ (1 + 4/T^3))

In general you cannot get an explicit expresion (i.e. in terms of radicals) when roots of higher order polynomials are taken into account. There is a fundamental mathematical barrier see e.g. Abel's Impossibility Theorem, Galois's Theorem. Only for special values of a and Λ you could get it. Root and RootSum objects are symbolic representations of certain well defined mathematical concepts. So for example you can evaluate them with arbitrary numerical accuracy. For a relation between RootSum and Root you can use Normal, e.g. Normal @ Integrate[ f[T, a, Λ], T]. More on Root objects you can find here How do I work with Root objects ?

You can find the limit of your ratio when T goes to Infinity :

Limit[  Integrate[ f[T, a, Λ1], T, Assumptions :> {a > 0, Λ1 > 0}]/
          Integrate[ f[T, a, Λ2], T, Assumptions :> {a > 0, Λ2 > 0}] ,
       T -> Infinity]

If you have values a, Λ1 and Λ2 you can compute the ratio for any temerature T :

ratio[ T_?NumericQ, a_?NumericQ, Λ1_?NumericQ, Λ2_?NumericQ] :=  
  NIntegrate[f[x, a, Λ1], {x, 0, T}]/  NIntegrate[f[x, a, Λ2], {x, 0, T}]
ratio[300, 10, 20, 15]
Plot[ ratio[T, 10, 20, 15], {T, 0, 300}]

enter image description here

One can see that the ratio is monotonic and tends to 1 quite rapidly.

share|improve this answer
Thnx for your help, guys! – molkee Jan 23 '13 at 2:24

Can set it up as below. You need not look at the intermediate results, hence can pretend you never ran into those RootSum things.

f[t_, lam_] := (4 a*t^3)/(4/3 a*t^4 + lam*(1 + 4/t^3)); 
f2[t_, lam_] := Integrate[f[t, lam], t];

quot = f2[t, lam0]/f2[t, lam1];

Here is the asymptotic behavior of the quotient as t --> infinity.

Limit[quot, t -> Infinity, Assumptions -> Element[a, Reals]]

(* Out[144]= 1 *)
share|improve this answer

Your Answer


By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.