In a DynamicModule, is it possible to use multiple EventHandler declarations? [duplicate]

Question

Possible Duplicate:
Wrapping EventHandler by Table

I am running Mathematica 7. However, I am new to using Dynamic, DynamicModule, EventHandler, and the like.

I would like to create a Graphics object containing numDisks Disk objects, where numDisks is a positive integer. I would like each of the Disk objects to be Red, Green, or Blue. The default color is Red, but if a disk is clicked, that disk goes to the next color, cyclically (Red-->Green-->Blue-->Red-->...). Is it possible to accomplish this using a DynamicModule and multiple EventHandler declarations?

I have tried the following. This code generates numDisks disks in a row. When the user clicks anywhere within the Graphics box, the color of all three disks changes to the next color in the sequence.

radius = 1;
numDisks = 3;

DynamicModule[{col = Red},
 EventHandler[
  Graphics[
   Table[{Dynamic[col], Disk[{2.5*(i - 1), 0}, radius]}, {i, 1, 
     numDisks}],
   PlotRange -> All],
  {"MouseClicked" :> (col = 
      col /. {Red -> Green, Green -> Blue, Blue -> Red})}]
 ]

However, what if I would like each of the numDisks Disk objects to have its own color, which can be changed independently of that of all of the other Disk objects? Is this possible? Can this be accomplished somehow using multiple EventHandler declarations? Thanks for your time.

Answer 1

You want to create an independent DynamicModule for each EventHandler. Otherwise, the single variable col will control the color for all of the disks, as you're witnessing. Your code can be rearranged as follows:

radius = 1;
numDisks = 3;

Graphics[Table[
  DynamicModule[{col = Red}, 
   EventHandler[{Dynamic[col], 
     Disk[{2.5*(i - 1), 0}, 
      radius]}, {"MouseClicked" :> (col = 
        col /. {Red -> Green, Green -> Blue, Blue -> Red})}]], {i, 1, 
   numDisks}], PlotRange -> All]

EDIT:

Okay...per your request in the comments, here's a variation which uses a single DynamicModule, but makes the col variable a list which is then referenced separately by the individual EventHandler constructs. The only thing that's tricky about this is that you have to inject the value of i from the Table inside of EventHandler and Dynamic using With.

radius = 1;
numDisks = 3;

DynamicModule[{col = Table[Red, {numDisks}]}, Column[{
   Graphics[
    Table[With[{i = i}, 
      EventHandler[{Dynamic[col[[i]]], 
        Disk[{2.5*(i - 1), 0}, 
         radius]}, {"MouseClicked" :> (col[[i]] = 
           col[[i]] /. {Red -> Green, Green -> Blue, 
             Blue -> Red})}]], {i, 1, numDisks}], PlotRange -> All],
   Dynamic[col]}]]

I wrapped this with a Column just to illustrate what the value of col is and the principle that you could access col from code outside of the graphic.