Plotting Fresnel function

Question

I am trying to plot the partial sums and the cesaro means of the function $\sqrt{|x|}$ and for $a_{n}$, I obtained the following code which contains FresnelS.

(-((Sqrt[2] FresnelS[Sqrt[2] Sqrt[n]])/n^(3/2)) - (Sqrt[2] FresnelS[Sqrt[2] Sqrt[Abs[n]]])/Abs[n]^(3/2) + (2 Sin[n \[Pi]])/n + (2 Sin[\[Pi] Abs[n]])/Abs[n])/(2 Sqrt[\[Pi]])

Now my question is is it possible to graph such function using Mathematica? I have tried many examples using trial and error and some of the my examples also contain BesselJ which can't be graph.

Hence I would like to know if it is true that if there is BesselJ and FresnelS in the code, then the graph cannot be drawn using Mathematica. Please correct me if I am wrong. I am graphing out its graph using this code:

f[x_] := Sqrt[Abs[Mod[x, 2 Pi, -Pi]]];
s[k_, x_] := ???
partialsums[x_] = Table[s[n, x], {n, {4}}]; 
c[n_, x_] := (1/n) Sum[s[m, x], {m, 0, n - 1}]
Plot[Evaluate[{f[x], partialsums[x], c[{4}, x]}], {x, -Pi, Pi},
PlotLegends -> {"f(x)=x", "Fourier, 4 terms", "Cesaro, 4 terms"}, 
PlotStyle -> {{Blue}, {Dashed, Thickness[0.006]}, {Red,Thickness[0.006]}}]

Answer 1

Coding Issue:

You can try to use DiscretePlot for the above expression out of the box in Mathematica!

DiscretePlot[
Evaluate@(-((Sqrt[2] FresnelS[Sqrt[2] Sqrt[n]])/
    n^(3/2)) - (Sqrt[2] FresnelS[Sqrt[2] Sqrt[Abs[n]]])/
  Abs[n]^(3/2) + (2 Sin[n \[Pi]])/n + (2 Sin[\[Pi] Abs[n]])/
  Abs[n])/(2 Sqrt[\[Pi]]), {n, 1, 150}]

Your code has minor typos! Before plotting always better to check what your functions are returning given an argument then you can spot the mistake in your code.

f[x_] := Sqrt[Abs[Mod[x, 2 Pi, -Pi]]];
s[k_, x_] :=Sum[(2 - 2 Cos[n \[Pi]] - n \[Pi] Sin[n \[Pi]])/(n^2 \[Pi]) Cos[
n x], {n, 1, k}]
partialsums[x_] = First@Table[N@s[n, x], {n, {4}}];
c[n_, x_] := (1/n) Sum[s[m, x], {m, 0, n - 1}];
Plot[Evaluate[{f[x], partialsums[x], c[4, x]}], {x, -Pi, Pi},
PlotStyle -> {{Blue}, {Dashed, Thickness[0.006]}, {Red,Thickness[0.006]}}]

Actual Answer:

Definition: Let ${a_n}_{n=0}^\infty$ be a sequence of real (or possibly complex numbers). The Cesaro mean of the sequence $\{a_n\}$ is the sequence $\{b_n\}_{n=0}^\infty$ with $$\begin{equation} b_n = \frac{1}{n+1} \sum_{i=0}^{n} a_i. \end{equation}$$

Code: Define the partial sum and the cesaro mean to take only Integer argument!

f[x_] := N@Sqrt[Abs[Mod[x, 2 Pi, -Pi]]]; 
part[k_?IntegerQ] := Total[(N@f[#]) & /@ Range[0, k]];
cesaro[k_?IntegerQ] := part[k]/(k + 1);

Testing: Check functions only evaluate for Integer argument.

Evaluate@{f[k], part[k], cesaro[k]} /. k -> 2

{1.41421, 2.41421, 0.804738}

Now plotting what you want!

DiscretePlot[Evaluate@{f[k], cesaro[k]}, {k, 1, 50}, Frame -> True, 
PlotStyle -> {{Red, PointSize[Medium]}, {Blue, Dashed}},Joined -> {False, True}]