# How to eliminate the zero real part of a purely imaginary number?

In Mathematica 9, a purely imaginary number, e.g. 0.9 I, will display as 0. + 0.9i in the output form. How can I eliminate the real part 0. in the output form?

-
To get rid of 0. you should use e.g. 4/5 I. –  Artes Jan 15 '13 at 12:37
You could use Round if the precision isn't of importance. –  gpap Jan 15 '13 at 12:45
Interesting, Chop doesn't do it. –  rcollyer Jan 15 '13 at 13:28

This is not a specific issue of Mathematica 9, we have the same in ver.8 unlike in ver.7.

Mathematica 8 and 9

First, looking at FullForm of these numbers :

FullForm /@ {0.9 I, 0 + 0.9 I, 0.9 + 0 I, 0.9 + 0. I}

{Complex[0., 0.9], Complex[0., 0.9], 0.9, Complex[0.9, 0.]}


(see e.g. Meaning of backtick in floating-point literal) and then examining this behvior :

{ Complex[0, 9/10], Complex[0, 0.9], Complex[0.9, 0], Complex[0.9, 0.]}
Chop @ %

{(9 I)/10, 0. + 0.9 I, 0.9, 0.9 + 0. I}
{(9 I)/10, 0. + 0.9 I, 0.9, 0.9       }


we can conclude that assuming the real part as an exact number it will be rewritten as a machine precission number given that the imaginary part is a machine precision number. Reverse need not be always true because e.g. Head[ Complex[0.9, 0]] is Real unlike Head[ Complex[0.9, 0.]]. Perhaps one might consider this as a bug since Chop unexpectedly doesn't work on the real part, while it works for the imaginary part in the above example. On the other hand rewriting Complex[0, .9] as 0. + 0.9I may be considered as a consistency issue.

Nevertheless you can still get the expected result using e.g. RootApproximant :

RootApproximant[0.9 I]

(9 I)/10


However if the imaginary part is not an algebraic number you cannot expect that RootApproximant will appear helpful and you'll have to work with exact numbers from the begining, e.g. this works well RootApproximant[ Sqrt[2.] I] while this doesn't RootApproximant[Pi I], nevertheless one needn't use it at all (Pi I yields I π).

{0 + Pi I, 0. + Pi I}

{ I π, 0. + 3.14159 I}


Mathematica 7

We have in ver.7 :

FullForm[0.9 I]

Complex[0, 0.9]


therefore :

0.9 I

0.9 I


nevertheless this behavior is not quite consistent, e.g. :

{ π I, 0. + π I, π + 0 I, π + 0. I}

{I π, 0. + 3.14159 I, π, 3.14159 + 0. I}


there is even worse problem :

{Pi + 0.9 I, Complex[Pi, 0.9]}

{3.14159 + 0.9 I, Complex[π, 0.9]}


To sum up the behaviour in Mathematica 8 and 9 seems to be more uniform than that of Mathematica 7 and therefore one can say it is an intentional issue. On the other hand Chop works well in ver. 7 :

{ Complex[0., 0.9], Complex[0.9, 0], Complex[0.9, 0.]}
Chop @ %

 {0. + 0.9 I, 0.9, 0.9 + 0. I}
{0.9 I, 0.9, 0.9}


while its defect in ver.8 and 9 is definitely undesirable.

-
+1 Thanks for the ping –  Rojo Jan 15 '13 at 16:06
@Rojo Thanks, just for completeness : In ver.7 Complex[Pi, 0.9] returns the same unlike Pi + 0.9 I, which yields 3.14159 + 0.9 I. Thus it looks like a bug. –  Artes Jan 15 '13 at 16:10

I don't seem to have this problem in version 7: 0.9 I outputs as 0.9 i where the i is the double-struck \[ImaginaryI]. Further FullForm[0.9 I] yields Complex[0, 0.9].

Nevertheless I would try:

MakeBoxes[Verbatim[Complex][r_, i_] /; r == 0, fmt_] :=
MakeBoxes[#, fmt] & @ Row @ {i, "\[MediumSpace]\[ImaginaryI]"}

-
In v7 Complex[2, 3], Complex[2, 3] both keep their exact parts exact? –  Rojo Jan 15 '13 at 15:06
@Rojo That's correct. –  Mr.Wizard Jan 15 '13 at 15:07
Interesting... In v9 it only happens for machine precision. It can keep mixed stuff but only if the precision is explicit. Keep your v7 :P –  Rojo Jan 15 '13 at 15:11
@Rojo The same behaviour is in ver.8 while in ver.7` that is not quite consistent. –  Artes Jan 15 '13 at 16:03