Working with PhysicalConstants

Question

I recently found the PhysicalConstants` package. First I thought this was nice, since I didn't have to look up some quantities all the time and copy them into the worksheet. But then I noticed the carried units. This is not automatically a bad thing, but it seems to me that they do not go together well, because Wolfram didn't just use base units. Consequently, if I use a quantity in Newton and divide it by a quantity in Meter/Second^2, the result will be Newton*Second^2/Meter, and not Kilogram. In my first try this made a huge mess in the result.

Is there a way to work with these in a useful way?

Answer 1

As J.M. comments, but opts not to post as an answer, you can use Convert in the Units package to convert between types. Be sure to read the documentation on that package.

Needs["Units`"]

Convert[(32.5 Newton)/(7 Meter/Second^2), Kilogram]

4.64286 Kilogram

You will also find use in the Automatic Units package described on the Wolfram Blog.

Answer 2

The units associated with physical constants do not play nicely with expressions that expect a numerical value. If you want only the numerical value of a constant, use Part. A motivating example:

Needs["PhysicalConstants`"];

Plot[1/Sqrt[1 - v^2/SpeedOfLight^2], {v, 0, 0.9 SpeedOfLight}]

 (* Plot::plln: Limiting value (2.69813*10^8 Meter)/Second in {v,0,0.9 SpeedOfLight} is not a machine-sized real number. >> *)    

c=SpeedOfLight[[1]]
 (* 299792458 *)

Plot[1/Sqrt[1 - v^2/c^2], {v, 0, 0.9 c}]

To see why using Part works, turn the constant into a list:

List@@SpeedOfLight
 (* {299792458, Meter, 1/Second} *)

or look at its FullForm:

FullForm@SpeedOfLight
 (* Times[299792458, Meter, Power[Second, -1]] *)    

Answer 3

With version 9, this is now possible using this method:

Plot[1/Sqrt[1 - v^2/QuantityMagnitude[UnitConvert[Quantity["SpeedOfLight"]]]^2], {v, 0,0.9*QuantityMagnitude[UnitConvert[Quantity["SpeedOfLight"]]] }]