Manipulate[]'ing complex roots of an equation using a 2D slider [closed]

Question

I want to make a demonstration of how the complex roots of a polynomial change when I alter the coefficients. Here is my attempt:

QuintRoots[t_] := Map[{Re[#], Im[#]} &, x /. NSolve[x^5 - x - t == 0, x]]

DrawRoots[t_] := ListPlot[QuintRoots[t], PlotRange -> {{-1.5, 1.5}, {-1.5, 1.5}}, 
                               PlotStyle -> PointSize[Large], AspectRatio -> Automatic]

Manipulate[DrawRoots[t[[1]] + I*t[[2]]], {t, {-1, 1}, {-1, 1}}]

QuintRoots[] and DrawRoots[] work exactly as I would expect. The final command produces a nice-looking 2D slider and ListPlot below it but, when I try to move the slider, it doesn't move.

A one dimensional slider, such as

 Manipulate[DrawRoots[E^{I*t}], {t, 0, 2 Pi}]

works fine. So does the documentation center's example of a 2D slider,

 Manipulate[ParametricPlot[{Sin[t + d[[1]]], Sin[t + d[[2]]]}, {t, 0, 2 Pi}], 
          {d, {0, 0}, {Pi, Pi}}]

PS Bonus question: If I can get this to work, I would also like to mark the points $\pm 3/ \sqrt{32}$ and $\pm 3 i /\sqrt{32}$ in the slider field, which are the points where we get multiple roots. Can this be done?

Answer 1

I've used this control before, in case it helps:

QuintRoots[t_] := 
 Map[{Re[#], Im[#]} &, x /. NSolve[x^5 - x - t == 0, x]]

DrawRoots[t_] := 
 ListPlot[QuintRoots[t], PlotRange -> {{-1.5, 1.5}, {-1.5, 1.5}}, 
  PlotStyle -> PointSize[Large], AspectRatio -> Automatic]

Manipulate[
 DrawRoots[t], {{t, 0.5}, 
  LocatorPane[
    Dynamic[{Re[t], Im[t]}, (t = Complex @@ Clip[#, {-1., 1.}]) &], 
    Labeled[Graphics[{White, Rectangle[{-1., -1.}, {1., 1.}], Blue, 
       Point[3/Sqrt[32] {{0, 1}, {0, -1}, {1, 0}, {-1, 0}}]}, 
      Axes -> True, ImageSize -> 130], Row[{"t = ", Dynamic[t]}]]] &, 
  ControlPlacement -> Left}]

Nice idea for a demonstration.