Plotting a 3D sphere i.e. how to vizualise the spanned volume $\int_0^{2\pi}\int_0^{\pi} d\theta d\phi$?

Question

I am trying to help this guy here to vizualise the integration volume. How can I plot the different integrals ie a ball and the ball adjusted by a trigonometric function?

Integrals needing visual cue: what does their spanned volume look like?

He was wondering why the first integral is not spherical. I want to provide some sort of visual cue in this kind of issues.

$$\int_0^{2\pi}\int_0^{\pi} d\theta d\phi = 2 \pi^2$$

$$\int_0^{2\pi}\int_0^{\pi} \sin\theta d\theta d\phi = 4 \pi$$

Answer 1

Here's a very basic demonstration:

Manipulate[
 ParametricPlot3D[{Sin[theta] Cos[phi], 
   Sin[theta] Sin[phi], Cos[theta]},
  {theta, 0, t}, {phi, 0, p},
  PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}],
 {t, 0.1, Pi}, {p, 0.1, 2 Pi}]

Answer 2

Here's another demonstration (CDF, v9 but works with lower versions) I use in class:

Manipulate[
 With[{P0 = \[Rho] (Sin[\[Phi]] {Cos[\[Theta]], Sin[\[Theta]], 0} + {0, 0, Cos[\[Phi]]}),
 $\[Theta]Color = Red, $\[Phi]Color = Darker[Blue], $\[Rho]Color = Brown},
      Graphics3D[{
        {PointSize[Medium], Point[P0], 
         Line[{{0, 0, 0}, #} & /@ (3 IdentityMatrix[3])], Opacity[0.3], 
         Line[{{0, 0, 0}, #} & /@ (-3 IdentityMatrix[3])]}, {
         {Opacity[0.3], 
          EdgeForm[Directive[Thickness[Medium], Opacity[0.3]]], 
          Polygon[{{0, 0, 0}, P0, {P0[[1]], P0[[2]], 0}}], $\[Theta]Color,
           EdgeForm[
           Directive[Thickness[Medium], 
            If[\[CapitalDelta]\[Rho] == 0 && \[CapitalDelta]\[Phi] == 0 && \[CapitalDelta]\[Theta] == 0, Opacity[1],
           Opacity[0.3]], $\[Theta]Color]], 
          Polygon[Append[
            Table[0.3 {Cos[t], Sin[t], 0}, {t, 
              Append[Range[0, \[Theta], 0.05], \[Theta]]}], {0, 0, 
             0}]], $\[Phi]Color, 
          EdgeForm[
           Directive[Thickness[Medium], 
            If[\[CapitalDelta]\[Rho] == 0 && \[CapitalDelta]\[Phi] == 0 && \[CapitalDelta]\[Theta] == 0,
           Opacity[1], Opacity[0.3]], $\[Phi]Color]], 
          Polygon[Append[
            Table[0.5 (Sin[t] {Cos[\[Theta]], Sin[\[Theta]], 0} + {0, 0, 
                 Cos[t]}), {t, 
              Append[Range[0, \[Phi], 0.05], \[Phi]]}], {0, 0, 0}]]},
         Line[{{P0, {0, 0, P0[[3]]}}, {{P0[[1]], P0[[2]], 0}, {P0[[1]], 0,
              0}}, {{P0[[1]], P0[[2]], 0}, {0, P0[[2]], 0}}}], 
         Point[DiagonalMatrix[P0]]
         },
        Which[
         \[CapitalDelta]\[Rho] == 0 && \[CapitalDelta]\[Phi] == 0 && \[CapitalDelta]\[Theta] == 0, 
          { Thick, $\[Rho]Color, Line[{{0, 0, 0}, P0}] },
         \[CapitalDelta]\[Rho] == 0 && \[CapitalDelta]\[Phi] == 0(*&&\[CapitalDelta]\[Theta]>0*), {
          First@
           ParametricPlot3D[\[Rho] (Sin[\[Phi]] {Cos[t], Sin[t], 0} + {0, 
                0, Cos[\[Phi]]}), {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, 
            PlotStyle -> Directive[Thick, $\[Theta]Color]]
          },
         \[CapitalDelta]\[Rho] == 0 &&(*\[CapitalDelta]\[Phi]>
          0&&*)\[CapitalDelta]\[Theta] == 0, {
          First@
           ParametricPlot3D[\[Rho] (Sin[s] {Cos[\[Theta]], Sin[\[Theta]], 
                 0} + {0, 0, 
                Cos[s]}), {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]}, 
            PlotStyle -> Directive[Thick, $\[Phi]Color]]
          },
         (*\[CapitalDelta]\[Rho]>
         0&&*)\[CapitalDelta]\[Phi] == 0 && \[CapitalDelta]\[Theta] == 0, {
          First@
           ParametricPlot3D[
            r (Sin[\[Phi]] {Cos[\[Theta]], Sin[\[Theta]], 0} + {0, 0, 
                Cos[\[Phi]]}), {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]}, PlotStyle -> Directive[Thick, $\[Rho]Color]]
          },
         \[CapitalDelta]\[Rho] == 0(*&&\[CapitalDelta]\[Phi]>
         0&&\[CapitalDelta]\[Theta]>0*), {
          First@
           ParametricPlot3D[\[Rho] (Sin[s] {Cos[t], Sin[t], 0} + {0, 0,  Cos[s]}),
              {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
              {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, Mesh -> None, 
            PlotStyle -> Directive[Lighter[$\[Rho]Color]]]
          },
         (*\[CapitalDelta]\[Rho]>0&&\[CapitalDelta]\[Phi]>
         0&&*)\[CapitalDelta]\[Theta] == 0, {
          First@
           ParametricPlot3D[ r (Sin[s] {Cos[\[Theta]], Sin[\[Theta]], 0} + {0, 0, Cos[s]}),
             {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
             {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]}, Mesh -> None, 
            PlotStyle -> Lighter[$\[Theta]Color]]
          },
         (*\[CapitalDelta]\[Rho]>
         0&&*)\[CapitalDelta]\[Phi] == 0(*&&\[CapitalDelta]\[Theta]>
         0*), {
          First@
           ParametricPlot3D[
            r (Sin[\[Phi]] {Cos[t], Sin[t], 0} + {0, 0, Cos[\[Phi]]}),
            {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]},
            {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]},
            Mesh -> None, PlotStyle -> Lighter[$\[Phi]Color]]
          },
         True(*\[CapitalDelta]\[Rho]>0&&\[CapitalDelta]\[Phi]>
         0&&\[CapitalDelta]\[Theta]>0*), {
          First@
           ParametricPlot3D[\[Rho] (Sin[s] {Cos[t], Sin[t], 0} + {0, 0, Cos[s]}),
               {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
               {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Rho]Color], Opacity[opacity]]], 
          First@
           ParametricPlot3D[
            r (Sin[s] {Cos[\[Theta]], Sin[\[Theta]], 0} + {0, 0, Cos[s]}),
               {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
               {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Theta]Color], 
               Opacity[opacity]]], 
          First@ParametricPlot3D[
            r (Sin[\[Phi]] {Cos[t], Sin[t], 0} + {0, 0, Cos[\[Phi]]}),
               {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]},
               {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Phi]Color], Opacity[opacity]]], 
          First@ParametricPlot3D[(\[Rho] + \[CapitalDelta]\[Rho]) (Sin[s] {Cos[t], Sin[t], 0} + {0, 0, Cos[s]}),
               {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
               {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Rho]Color], Opacity[opacity]]], 
          First@ParametricPlot3D[
            r (Sin[s] {Cos[\[Theta] + \[CapitalDelta]\[Theta]], 
                 Sin[\[Theta] + \[CapitalDelta]\[Theta]], 0} + {0, 0, Cos[s]}),
               {s, \[Phi], \[Phi] + \[CapitalDelta]\[Phi]},
               {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Theta]Color], 
               Opacity[opacity]]], 
          First@ParametricPlot3D[
            r (Sin[\[Phi] + \[CapitalDelta]\[Phi]] {Cos[t], Sin[t], 0} + {0, 0, Cos[\[Phi] + \[CapitalDelta]\[Phi]]}),
               {r, \[Rho], \[Rho] + \[CapitalDelta]\[Rho]},
               {t, \[Theta], \[Theta] + \[CapitalDelta]\[Theta]}, Mesh -> None, 
            PlotStyle -> 
             Dynamic@Directive[Lighter[$\[Phi]Color], Opacity[opacity]]]
      }
     ]
    },
   SphericalRegion -> True, PlotRange -> 2, Lighting -> "Neutral"
   ]],
 Row[{Control[{{\[Rho], 1}, 0, 2, ImageSize -> Small}], 
   Control[{\[CapitalDelta]\[Rho], 0, 1, ImageSize -> Small}]}, 
  Spacer[1]],
 Row[{Control[{\[Phi], 0, \[Pi], ImageSize -> Small}], 
   Control[{\[CapitalDelta]\[Phi], 0, \[Pi], ImageSize -> Small}]}, 
  Spacer[1]],
 Row[{Control[{\[Theta], 0, 2 \[Pi], ImageSize -> Small}], 
   Control[{\[CapitalDelta]\[Theta], 0, 2 \[Pi], 
     ImageSize -> Small}]}, Spacer[1]],
 {{opacity, 1}, 0, 1}, ControlPlacement -> Left
 ]

[Sorry it didn't work at first. Pasting the code from Mathematica inserted spaces in some variable names -- didn't expect that. Thanks for your patience.]

I might add that the reason for submitting it was that it shows, if one moves the ϕ slider, that the surface area element $dS$ or volume element $dV$ decreases as ϕ moves toward 0, or $\pi$, which is in part what his question was about.