Grid without lines, but with dots

Question

I want to build a grid to look like the top-left table shown below, but without an outside frame.

Here is what I've tried to do:

a = {
    {, , 2, 2, 2, 2,},
    {, , 3, , 2, 0, 3},
    {, 2, 2, , 3, , 3},
    {2, 2, 2, , , , 2},
    {2, 3, , , 1, ,},
    {2, , 1, 3, , ,},
    {3, 3, 3, 2, 3, , 3}
    };

f = Riffle[#, "\[CenterDot]", {1, -1, 2}] &;

f /@ Transpose[f /@ a] // Transpose // Grid

What I don't like in my result is that I have three times more dots than I need. And I don't know how to fix it. Suggestions?

Answer 1

Depending on what you are doing, this might be better solved by using Graphics commands and building the display as a graphics object rather than a textural output. This however does the trick with just inserting elements into the grid shape:

 gridDots[a_] := Module[{
   rowspacing = Riffle[#, " ", {1, 1 + Last@Dimensions[a] 2, 2}] &,
   colspacing = Riffle[#, {Flatten[ConstantArray[{".", " "}, 1 + Last@Dimensions@a]]},
                        {1, 1 + 2 First@Dimensions@a , 2}] &},
 colspacing[rowspacing /@ a]
 ]

 gridDots[a] // Grid

Answer 2

Maybe

evenrows = Prepend[#, " "] & /@ (Join @@ Thread[{#, " "}] & /@ a);
oddrows = (Join @@ ConstantArray[{"\[CenterDot]", " "}, 8]);
Grid@Riffle[evenrows, {oddrows}, {1, -1, 2}]

?

Answer 3

Yet another option:

  Grid[SparseArray[
  {{i_, j_} /; OddQ[i] && OddQ[j] :> "\[CenterDot]",
   {i_, j_} /; EvenQ[i] && EvenQ[j] :> a[[i/2, j/2]]}
  , {2 Length[a] + 1, 2 Length[a] + 1}, ""]]