Sound data Import Export

Question

Can't regain the data after Export.

Create an array of sampled amplitude values:
2. Visualize as sound
3. Save it
4. Get it back
5. ???

sound = RandomReal[1, {500}];  
ListPlay[sound]  
Export["test.txt", sound];  
in=Import["test.txt"]  
ListPlay[in]

A second example.
Take data from a WAV sound,
Export it,
reImport it,
play it.

tubadat = ExampleData[{"Sound", "Tuba"}, "Data"];  
Export["TubaDat.dat", tubadat];  
in = Import["TubaDat.dat"];  
ListPlay[in]  

It is not the original sound.

Answer 1

Try Export["~/Desktop/test.txt", Compress@sound] and in = Uncompress@Import["~/Desktop/test.txt"]. The way you did it, it gets imported as a string. There's other ways, but the one I present is what I always use to export/import arbitrary data structures: it's cross-platform and robust (as far as I can tell).

Regarding the second example and the comments:

tubadat = ExampleData[{"Sound", "Tuba"}, "Data"]; 
ListPlay[tubadat, SampleRate -> 22050] 
Export["~/Desktop/TubaDat.txt", Compress@tubadat]; 
in = Uncompress@Import["~/Desktop/TubaDat.txt"]; 
ListPlay[in, SampleRate -> 22050, PlayRange->{-1,1}] 
tubadat == in 

works; the sounds seem identical and tubadat==in evaluates to True. Note that setting the sample rate is necessary (it defauls to 8k).

To summarise, you need to

• make sure you're importing in the right format (your original code ended up importing as a string)

• fix the sample rate as it defaults to the wrong values for this case.

• possibly fix the max amplitude (otherwise the sample is amplified or clipped)

Answer 2

The 4th line needs correction:

in = Import["test.txt", "Data"] // Flatten

Now it will work - you need to read up on import/export of data on Documentation. This is fixes your specific code. But there are many ways to do this. For example to use "test.dat" format is better (no "Data" specification needed in Import). Or exporting sound itself (not the data) will work too - with the advantage that you can play it in other software:

data = RandomReal[1, 500];
sound = ListPlay[data];
Export["test.wav", sound];
Import["test.wav"]