Making the TableForm output into two columns

Question

I have a program that calculates Christoffel symbols for a given metric, and the output I'm getting now is such that I have every calculated symbol in one column like this:

I'd like that I could have that in two columns:

1. \Gamma^1_2,3=... \Gamma^2_1,3= ...
2. \Gamma^1_3,2=... \Gamma^3_1,3= ...
3. \Gamma^2_2,2=... \Gamma^3_1,2= ...
4. ...

I looked at the documentation, and I tried something with that, but all I could do is to widen the spacing between \Gamma and the results -.-"

Here's thee code:

Clear[coord, metric, inversemetric, affine, \[Tau], r, \[Theta], \
\[CurlyPhi]]

n := 4

coord := {\[Tau], r, \[Theta], \[CurlyPhi]}

metric := 
 2 G J \[CapitalOmega][\[Theta]]^2*{{-(1 + (1 - \[CapitalLambda][\
\[Theta]]^2)), 0, 0, 2 r \[CapitalLambda][\[Theta]]^2}, {0, 1/(
    1 + r^2), 0, 0}, {0, 0, 1, 0}, {2 r \[CapitalLambda][\[Theta]]^2, 
    0, 0, \[CapitalLambda][\[Theta]]^2}}

inversemetric := Simplify[Inverse[metric]]

affine := 
 affine = Simplify[
   Table[(1/2) Sum[
      inversemetric[[\[Mu], \[Rho]]] (D[metric[[\[Rho], \[Nu]]], 
          coord[[\[Lambda]]]] + 
         D[metric[[\[Rho], \[Lambda]]], coord[[\[Nu]]]] - 
         D[metric[[\[Nu], \[Lambda]]], coord[[\[Mu]]]]), {\[Rho], 1, 
       n}], {\[Nu], 1, n}, {\[Lambda], 1, n}, {\[Mu], 1, n}]]

listaffine := 
 Table[If[UnsameQ[affine[[\[Nu], \[Lambda], \[Mu]]], 
     0], {Style[
      Subsuperscript[\[CapitalGamma], 
       Row[{coord[[\[Nu]]], coord[[\[Lambda]]]}], coord[[\[Mu]]]], 
      18], "=", 
     Style[affine[[\[Nu], \[Lambda], \[Mu]]], 14]}], {\[Lambda], 1, 
    n}, {\[Nu], 1, n}, {\[Mu], 1, n}] // FullSimplify

TableForm[
  Partition[DeleteCases[Flatten[listaffine], Null], 
   3]] // FullSimplify

Answer 1

Ok, here is the code. Made small changes at the very end. I am sure there is a more elegant way to do it. But I simply added the counter column at the left using Insert[] and added the "=" using a Map. That is pretty much it.

Changes:

1. changed your listaffine line to remove "=" that you had there.
2. Partition it to 4 column now.
3. use Map to format it with "="
4. insert the counters column

i.e. 1 line changed. 2 new lines. that is it (you can use online diff website to see the difference also)

 (*... every thing from top to here was not changed... *)
 listaffine := 
  Table[If[UnsameQ[affine[[\[Nu], \[Lambda], \[Mu]]], 
      0], {Style[
       Subsuperscript[\[CapitalGamma], 
        Row[{coord[[\[Nu]]], coord[[\[Lambda]]]}], coord[[\[Mu]]]], 
       18], Style[affine[[\[Nu], \[Lambda], \[Mu]]], 
       14]}], {\[Lambda], 1, n}, {\[Nu], 1, n}, {\[Mu], 1, n}] // 
   FullSimplify;

data = {#[[1]], "=", #[[2]], #[[3]], "=", #[[4]]} & /@ 
   Partition[DeleteCases[Flatten[listaffine], Null], 4];

data = Insert[data[[#]], #, 1] & /@ Range[Length[data]];
TableForm[data] (*or Grid[data] or anything else you like *)