Can mathematica show me a fraction with a repeating decimal notation?

Question

The value of 3/817 when expressed using the N[3/817, 100] shows me data without helping me see the repeating patterns:

After I mess around with the results in Notepad, I can reformat it in notepad so I see the repeating decimals, but what I would really like to see is a line over the repeating group of digits, like this:

Answer 1

Here's another approach:

repeatingForm[x_Rational] := Module[
   {realDigits, integerPart, fractionalPart, start, repeat, exp},
   integerPart = IntegerPart[x];
   fractionalPart = FractionalPart[x];
   realDigits = RealDigits[fractionalPart];
   Which[
    MatchQ[realDigits, {{__Integer, {__Integer}}, _Integer}],
    start = Most[First[realDigits]];
    repeat = Last[First[realDigits]],
    MatchQ[realDigits, {{{__Integer}}, _Integer}],
    start = {};
    repeat = Last[First[realDigits]],
    MatchQ[realDigits, {{__Integer}, _Integer}],
    start = First[realDigits];
    repeat = {}
    ];
   exp = Last[realDigits];
   If[exp < 0,
    start = Join[Table[0, {-exp}], start]];
   If[Length[repeat] > 0,
    Row[Flatten[{N[integerPart], start, OverBar[Row[repeat]]}]],
    Row[Flatten[{N[integerPart], start}]]
    ]
   ];

Let's try it on Vitaliy's original set of data points. (I guess he deleted this portion.)

data = {98464/3, 2209604/53, 1654407/32, 4695213/44, 2608035/32, 
  1060220/31, 1254299/54, 3180989/37, 1120269/83, 6084320/73};
repeatingForm /@ data // Column

Answer 2

--- final function ---

I recommend reading article Repeating Decimal. Function RealDigits gives you complete information:

RealDigits[237/14]

{{1, 6, 9, {2, 8, 5, 7, 1, 4}}, 2}

as seen from

N[237/14, 30]

Write a function that shows an overbar and period:

RepeatingDecimal[x_Rational] := With[{tv = RealDigits[x]},
  Subscript[Row[Insert[Cases[tv[[1]], _Integer]~Join~
      (OverBar /@ Flatten[Cases[tv[[1]], _List]]), ".", tv[[-1]] + 1]]
   , Length[tv[[1, -1]]]]]

Test it out:

dat = DeleteCases[(RandomInteger[{1, 10^7}, 5]/RandomInteger[{10, 50}, 5]), _Integer]

Grid[{RepeatingDecimal[#], N[#, 20]} & /@ dat, Alignment -> Left]

--- via internet connection ---

You can use built-in Wolfram Alpha integration:

RepDec[x_Rational] := 
  WolframAlpha[ToString[InputForm[x]], {{"RepeatingDecimal", 1}, "Content"}]

Test this out:

RepDec[4692085/38]

Answer 3

This code will automatically write rationals as repeating (or finite) decimals. The decimals have a tooltip that show which rational they represent and are automatically truncated for long repeating sections. The decimal is not editable, so that it can't be broken when copying (this can probably be improved upon). To edit the number, select it and convert to inputform.

Unprotect[Rational];
Rational /: MakeBoxes[r : Rational[_Integer, _Integer], _] := 
 With[{trunc = 45, d = RealDigits[FractionalPart[r]]},
  With[{boxes = ToBoxes[Style[Tooltip[
        Row[Flatten@{IntegerPart[r], ".", ConstantArray[0, -d[[2]]],
           If[Head[d[[1, -1]]] === List, {Most@First@d, OverBar[                  
              Row[If[Length[#] > trunc, Join[#[[1 ;; trunc]], 
                {"\[LeftSkeleton]", Length@# - trunc, "\[RightSkeleton]"}], #]]&@d[[1, -1]]]}, 
              First@d]}],
        Row[{Numerator[r], " /", Denominator[r]}]], 
       Selectable -> False, ShowStringCharacters -> False]
      ]},
   InterpretationBox[boxes, r]
    ]]
Protect[Rational];

e.g.,

Here's examples of truncating long repeating decimals
Note that for complicated rational numbers, this code to format them as repeating decimals can take some time, simply due to calculating and displaying the RealDigits.