Make a slider controlling a generated character's code value

Question

If I execute the following code:

char = 97;
Slider[Dynamic@ToExpression@FromCharacterCode@char, {0, 5}]

the slider will fail to change the value of a.

How do you make this work, when the expression has to be generated with FromCharacterCode or similar?

Note:

ToExpression@FromCharacterCode@97 == a

Answer 1

Perhaps the simplest thing would be to put the string "Dynamic@" inside ToExpression:

Slider[ToExpression["Dynamic@" <> FromCharacterCode@char], {0, 5}]

This creates a slider which controls the value of the symbol a, which I think is what you are asking for.

Answer 2

How about using With?

char = 97;
With[{var = ToExpression@FromCharacterCode@char},
  Slider[Dynamic@var, {0, 5}]
]

or, if a already exists, following Simon Woods' suggestion:

char = 97;
With[{var = ToExpression[FromCharacterCode@char, InputForm, Unevaluated]},
  Slider[Dynamic@var, {0, 5}]
]

Answer 3

I think you mean something like this:

Clear[char];
{Slider[Dynamic[char], {67, 97, 1}], Dynamic[FromCharacterCode[char]]}

The syntax in your question was incorrect because the dynamic variable in the first argument of Slider can't be a protected function name.

Edit

You also had a ToExpression in your question. That can be added in this answer too, obviously by writing ToExpression@FromCharacterCode. Then you just have to make sure your character range doesn't include characters that yield an error when fed into ToExpression.

Edit 2 In response to the comment, I think what you should do is to write

a = Dynamic[ToExpression@FromCharacterCode[char]]

with the above slider (or some version of it).

Answer 4

Here's another formulation:

Slider[Dynamic @@ ToHeldExpression @ FromCharacterCode @ char, {0, 5}]