How to change step size of ListPlot

Question

The command ListPlot will plot lists with a unit step. Is there any way to change the step size of this?

Answer 1

Two approaches:

1. Use the option DataRange (in the Options section of ListPlot in the documentation center.

2. ListPlot also takes a list of x,y pairs. So another option is transforming your input data (a list of y values) to a list of x,y pairs

Answer 2

Lists don't save the value they have been generated with. Consider the example of plotting a sine using a discrete point set:

data = Table[Sin[2 Pi x], {x, 0, 1, 0.05}];
ListPlot[data]

Notice the nonsense values on the $x$ axis.

There are three possible solutions for this, all of which give the following plot as a result:

Using DataRange to manually specify the domain of the data in ListPlot

data = Table[Sin[2 Pi x], {x, 0, 1, 0.05}];
ListPlot[data, DataRange -> {0, 2 Pi}]

The disadvantage of this approach is that the data range is not known to the plot, and it has to be entered by the user manually. If the data itself changes, the plot will still assume these manual numbers, even if the domain is now much larger (consider expanding the above table to run from 0 to 20).

Embedding the data range into the list

data = {
        Table[Sin[2 Pi x], {x, 0, 1, 0.05}],
        DataRange -> {0, 2 Pi}
       };
ListPlot @@ data

Disadvantage: the DataRange option is only useful for a couple of functions. When you're planning to further modify the data, you will always have to pay attention that data doesn't save the data on the first level, but on the second one of this nested list.

Incorporating the x values when generating the data

data = Table[{2 Pi x, Sin[2 Pi x]}, {x, 0, 1, 0.05}];
ListPlot[data]

The disadvantage of this approach is of course a more complicated list structure, as well as about twice the amount of data.

Answer 3

Perhaps you are looking for DataRange?

SeedRandom[1];
dat = RandomReal[5, 20];
ListLinePlot[dat, DataRange -> {1, 5}]