Threading Distribute[]

Question

I wish to use Distribute[p.(q+r)+m] to get p.q+p.r+m. However, Distribute apparently does not thread through all parts of the expression. What should I do instead?

Answer 1

You don't give a lot of context about how the target expression is generated (interactively or via code). The documentation for Distribute indicates that it won't automatically map down through an expression. But, one way to do this comes to mind.

Via code, using ReplaceAll and a replacement rule:

expr=p.(q+r)+m
expr /. d : HoldPattern[Dot[_, Plus[_, _]]] :> Distribute[d]
(* m + p.q + p.r *)

Answer 2

You could also define special symbols that distribute themselves when they get combined with Plus under a Dot operation. Here I denote those symbols with a hat:

Clear[OverHat];
OverHat /: Dot[x___OverHat, Plus[y__OverHat], z___OverHat] := 
 Plus @@ Thread[Dot[x, {y}, z]]

Then you can enter your expression like this:

OverHat[m] + OverHat[p].(OverHat[q] + OverHat[r])

where the OverHat is more easily input using the shortcut Ctrl7+^ to get this:

Answer 3

  p.(q + r) + m /. Dot -> Composition[Distribute, Dot]
  (* m + p.q + p.r *)

  Log[p.(q + Log[r + s])] + Log[a + b] + m /.  Dot -> Composition[Distribute, Dot]
  (* m + Log[a + b] + Log[p.q + p.Log[r + s]] *)