Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

How to select and delete all Output cells in multiple notebooks programmatically without needing to (manually) opening them?

How to define a hot key for deleting all Output cells within a notebook from that notebook?

share|improve this question
    
Maybe some useful information here. –  b.gatessucks Nov 1 '12 at 15:06
    
I think this is answered in the answers to this, as @b.gatessucks points out. –  acl Nov 1 '12 at 15:21
    
I assume you know about the delete all output cell option in the Cell menu? If so it should be straightforward to assign a key to this (cf @acl and @b.gatessucks)? But may be you want a non interactive option? –  chris Nov 1 '12 at 15:37
    
Actually the linked in the comments thread does not show simplest menu-wise solution. –  Vitaliy Kaurov Nov 1 '12 at 15:41
1  
Yes, you put it in $UserBaseDirectory. If the original is at $InstallationDirectory/foo/bar/file.tr, then you mirror the tree and copy it to $UserBaseDirectory/foo/bar/file.tr –  rm -rf Nov 1 '12 at 16:03
show 2 more comments

4 Answers 4

up vote 11 down vote accepted

Without adressing the hotkey issue (you could add a menu entry, or simply put an appropriate Button in your notebook), here is one variety that uses NotebookDelete and can be modified to include different CellStyles as well. The first argument nb defines which notebook to work on, the second argument styles defines the styles of to-be-deleted cells:

CleanNotebook[nb_: SelectedNotebook[],styles_: {"Output"}] := 
   (NotebookFind[nb, #, All, CellStyle];
    NotebookDelete[nb];) & /@ styles

Together with NotebookOpen, NotebookSave and NotebookClose and related functions you should be able to work on arbitrary notebooks programmatically.

Example:

docpath = 
  ToFileName[{$InstallationDirectory, "Documentation", "English", 
    "System"}, "ExampleData"];

nb = NotebookOpen[ToFileName[docpath, "document.nb"]]

Mathematica graphics

CleanNotebook[nb]

Take care what other styles you choose, they´ll be gone for good...

Edit: You may also use the Option Visbible->False to supress the opening of a window for this notebook. This seems useful for batch processing (especially if Dynamic stuff is involved, because this will probably not trigger if invisible), but takes additional care to save and close programmatically because invisble windows do not show up in the menu bar.

Example:

doc = ToFileName[{$InstallationDirectory, "Documentation", "English", 
    "System", "ExampleData"}, "document.nb"];

bak = ToFileName[$TemporaryDirectory, "document_clean.nb"];

nb = NotebookOpen[doc, Visible -> False];
CleanNotebook[nb];
NotebookSave[nb, bak]
NotebookClose[nb]

NotebookOpen[doc];    
NotebookOpen[bak, Visible -> True];

There is still an issue with the Visible option being saved in the backup notebook and hiding when reopened (thus re-setting Visible->True).

share|improve this answer
    
Is that a typo that the second instance of SelectedNotebook[] should be nb? –  Problemaniac Nov 2 '12 at 2:02
    
If i'm applying the function should the first argument be simply the file name (a _String expression) or that wrapped with NotebookOpen? –  Problemaniac Nov 2 '12 at 2:32
    
@MonkeyKing: Correct! Fixed... –  Yves Klett Nov 2 '12 at 6:49
    
@MonkeyKing: If you use NotebookOpen it returns a NotebookObject. This NotebookObject can be used as a handle for subsequent actions. See edit. –  Yves Klett Nov 2 '12 at 6:57
    
If you use this method on many notebooks, wouldn't it cause many notebooks quickly open on your screen and close? Is there a way to open them for kernel but not visually to human? –  Problemaniac Nov 2 '12 at 14:41
show 4 more comments

This is how you do it through menus, As correctly noted in the comment this is equivalent to the shortcut ALT+C >> L >> ENTER.

enter image description here

share|improve this answer
    
I find the keyboard shortcut Alt c l Enter much faster –  Rolf Mertig Nov 1 '12 at 19:19
    
@RolfMertig yes, noted in the post, thanks. –  Vitaliy Kaurov Nov 1 '12 at 19:58
    
I'm using Alt-C UpArrow Enter, so I really hope that entry will stay the second to last in future versions :-) –  Albert Retey Nov 1 '12 at 21:46
    
What about in Mac? Alt+c types in ç for me. –  Problemaniac Nov 2 '12 at 1:09
add comment

Update December 6th: There is an updated version (plus a bug fix for M9) working on Windows, MacOSX and Linux available and installable by

  Import["http://www.mertig.com/mykeys.m"]

On Windows (Mac does not work yet): Execute the following code in a notebook and restart Mathematica.

Then hitting F4 will delete all Output, Print and Message cells in the selected notebook, while pressing F8 will do so in all open notebooks which are not Wolfram Documentation notebooks. This was more difficult to program than it should be ...

$OverWriteUserBaseDirectoryKeyEventTranslations = True;
    mymenuitems="
       (* Delete all Output, Message and Print cells in the selected notebook *)
                 Item[KeyEvent[\"F4\"(*, Modifiers -> {\"Control\",\"Shift\"}*)], 
                 KernelExecute[
                   Module[{nb = SelectedNotebook[]},
                    Scan[Function[c, If[NotebookFind[nb, c, All, CellStyle, AutoScroll -> False] =!= $Failed,
                                    NotebookDelete[nb, AutoScroll -> False]]  
                             ],
                     {\"Message\", \"Output\", \"Print\"}
                    ];
                 SelectionMove[nb,After,Notebook];
              ]
            ], MenuEvaluator -> Automatic ],\n
  (* Delete all Output, Message and Print cells in all open notebooks *)
             Item[KeyEvent[\"F8\"], 
             KernelExecute[
               Module[{nbs = Notebooks[]},
                Quiet[nbs = Select[nbs,  Function[z, Not[StringMatchQ[ Replace[ NotebookFileName[z], $Failed :> \"\"],
                                                                           \"*Wolfram*Documentation*\"]]]]];
                    Do[
                    Scan[Function[c, If[NotebookFind[nb, c, All, CellStyle, AutoScroll -> False] =!= $Failed,
                                    NotebookDelete[nb, AutoScroll -> False]]  
                             ],
                     {\"Message\", \"Output\", \"Print\"}
                    ];
                 SelectionMove[nb,After,Notebook],
                {nb,nbs}]
              ]
            ], MenuEvaluator -> Automatic ],";
Quiet@CreateDirectory@FileNameJoin[{$UserBaseDirectory,"SystemFiles","FrontEnd","TextResources",$OperatingSystem}];
mykeyeventtrans=FileNameJoin[{$UserBaseDirectory,"SystemFiles","FrontEnd","TextResources",$OperatingSystem,"KeyEventTranslations.tr"}];
If[$OverWriteUserBaseDirectoryKeyEventTranslations===True,
    If[FileExistsQ[mykeyeventtrans],DeleteFile@mykeyeventtrans];
    CopyFile[FileNameJoin[{$InstallationDirectory,"SystemFiles","FrontEnd","TextResources",$OperatingSystem,"KeyEventTranslations.tr"}],mykeyeventtrans]
];
keytext=Import[mykeyeventtrans,"Text"];
mykeytext=StringReplace[keytext,"EventTranslations[{":>StringJoin["EventTranslations[{\n",mymenuitems,"\n"]];
Export[mykeyeventtrans,mykeytext,"Text"];
share|improve this answer
    
How about including Undo option? Instead of NotebookDelete[..] use MathLink`CallFrontEnd[FrontEnd`SelectionAddCellTags[nb, {"$deleted"}]] and then just before the last command SelectionMove[..] insert this If[NotebookFind[nb, "$deleted", All, CellTags, AutoScroll -> False] =!= $Failed, MathLink`CallFrontEnd[FrontEnd`SelectionRemoveCellTags[nb, {"$deleted"}]]; FrontEndTokenExecute["Clear"]]; –  Vladimir Apr 14 '13 at 18:37
add comment

Yves Klett's answer is still pretty simple, but I thought I would add an alternative V9 solution using Cells

nb = EvaluationNotebook[]; (* change as desired *)
cells = Cells[nb, CellStyle -> {"Output"}];
CopyToClipboard @ NotebookRead @ cells; (* optional - saves cells for pasting *)
NotebookDelete[cells]

Beware: Pasting the cells back into the notebook will replace the current selection. It is not an "undo" command. It potentially could save an enormous amount of data, which you might not always want.

Here's a modification of Yves Klett's function CleanNotebook:

deleteStyle[nb_: SelectedNotebook[], styles_: {"Output"}] :=
  With[{cells = Flatten[Cells[nb, CellStyle -> {#}] & /@ styles]},
    (* CopyToClipboard@NotebookRead@cells; (*optional*) *)
    NotebookDelete[cells]
   ]

Again, there's no "undo" for this, so be careful.

share|improve this answer
add comment

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.