Median marker style in BoxWhiskerChart

Question

I was trying to adapt the BoxWhiskerChart to obtain a minimalistic quartile plot, like this:

What I obtained is the plot below that is, however, unsatisfying; the median markers should be circles, but they are instead slightly squared.

The code:

data = Table[
   RandomVariate[NormalDistribution[\[Mu], 1], 100], {\[Mu], 
    RandomInteger[{-2, 2}, 10]}];
filledCircle[size_] := Graphics[{Black, Disk[]}, ImageSize -> size];
BoxWhiskerChart[data,
  {{"Whiskers", Black},
   {"MedianMarker", filledCircle[10], Black},
   {"Fences", None}},
  ChartBaseStyle -> White,
  Frame -> False,
  Method -> {"BoxRange" -> (Quantile[#, 
        Range[0, 1, 1/4], {{1/2, 0}, {0, 1}}] &)}
  ]

As an alternative, I've tried to rasterize the circles; the shape is now correct, but we get a lateral shift of the median marker.

filledCircle[size_] := Rasterize[Graphics[{Black, Disk[]}, ImageSize -> size]];

Does anyone have a better approach or solution? Or should I just build my own function?

Answer 1

The disks aren't getting antialiased. (This is probably leaking from turning off antialiasing for the lines and rectangles.)

If you turn antialiasing back on:

filledCircle[size_] := 
    Graphics[{Black, Style[Disk[], Antialiasing -> True]}, 
        ImageSize -> size]

it should look better:

Answer 2

I would use a FilledCircle rather than creating the Disk:

data = Table[RandomVariate[NormalDistribution[\[Mu], 1], 100], {\[Mu], 
RandomInteger[{-2, 2}, 10]}];


BoxWhiskerChart[data,
                {{"Whiskers", Black},
                {"MedianMarker", Style[\[FilledCircle], 45], Black},
                {"Fences", None}},
                ChartBaseStyle -> White,  Frame -> False,  
                Method -> {"BoxRange" -> 
                (Quantile[#,Range[0, 1, 1/4], {{1/2, 0}, {0, 1}}] &)}
                ]

Here is an example with the typical format overlaid:

Show[
      BoxWhiskerChart[data,
                     {{"Whiskers", Black},
                     {"MedianMarker",Style[\[FilledCircle], 30], Black},       
                     {"Fences", None}},
                     ChartBaseStyle -> White, Frame -> False, 
                     Method -> {"BoxRange" ->
                    (Quantile[#,Range[0, 1, 1/4], {{1/2, 0}, {0, 1}}] &)}],
      BoxWhiskerChart[data, {{"Fences", None}},ChartBaseStyle ->Opacity[.75]]
   ]