Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I'd like to know which algorithm is used to test if two graphs are isomorphic?

share|improve this question
6  
Help > About Mathematica > Credits lists, amongst other programs, Nauty 2.4. –  Daniel Lichtblau Oct 31 '12 at 18:27

1 Answer 1

up vote 11 down vote accepted

As Danny points out, you can find the list of licensed software using the "About Mathematica..." box, available under the Mathematica menu on my Macintosh and under the Help menu for a PC. As a dialog box, that Notebook is not searchable and a bit inconvenient to work with. If we open it with a text editor and examine the contents, we find that the cells containing the lincense information are all "LicenseText" cells and that the first such cell for each licensed system is in Bold. Thus, we can grab and group information on all licensed software as follows:

aboutBoxFile = FileNameJoin[{$InstallationDirectory,
  "SystemFiles", "FrontEnd", "TextResources", "AboutBox.nb"}];
licenseCells = Cases[Import[aboutBoxFile],
  Cell[_, "LicenseText", OptionsPattern[]], Infinity];
splitCells = Split[licenseCells, 
  !MemberQ[Options[#2], FontWeight -> "Bold"] &];
splitCells // Length

(* Out: 112 *)

Seems to indicate that there are 112 pieces of software licensed (in some way) for use in Mathematica. The last four groups are actually just statements of various open source software licenses, so there's really just 108. We can place all this information in a conveniently formatted notebook as follows.

createGroup[{head_, rest___}] := Module[{sectionHeader},
  sectionHeader = First[head];
  Cell[CellGroupData[
    Join[{Cell[sectionHeader, "Section", ShowGroupOpener -> True]},
      Map[Cell[First[#], "Text"] &, {rest}]], Closed]]];
NotebookPut[Notebook[Join[{
  Cell["Software licensed for use in Mathematica", "Title"]},
  createGroup /@ splitCells],
  "WindowTitle" -> "Licensed software"]];

This should open a notebook that looks like the following, after opening one of my favorite sections. Nauty version 2.4 is the 75th item on the list.

enter image description here

share|improve this answer
    
Very nice! I actually needed this today (and just used it). Was looking for some old software to see if we were using it under license. –  Daniel Lichtblau Oct 31 '12 at 21:31
    
@DanielLichtblau Awesome! –  Mark McClure Oct 31 '12 at 21:33
    
Thanks for the reference to Nauty. –  Mario Stefanutti Oct 31 '12 at 23:59

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.