How can I fill-in this Pentagram?

Question

This is my code:

Graphics[{EdgeForm[Yellow], Yellow, Polygon[Table[{Cos[t], Sin[t]}, {t, 0, 4 π, (4 π)/5}]]}]

which gives this:

but I want to get:

How?

Answer 1

You could use the undocumented functions SimplePolygonPartition and PolygonCombine:

poly = Polygon[Table[{Cos[t], Sin[t]}, {t, 0, 4 \[Pi], (4 \[Pi])/5}]];

Graphics`Mesh`MeshInit[];
poly2 = PolygonCombine@SimplePolygonPartition@poly;
Graphics[{EdgeForm[Black], Yellow, poly2}]

Answer 2

The problem is that you have overlapping areas. The way this is handled by Mathematica is twice covered it will be negated and not be filled.

You could draw it by creating both the points at the tips and the valleys:

 Graphics[{Yellow,
 Polygon[
 Reverse@Riffle[
   Table[{Cos[t], Sin[t]}, {t, 0, 2 π, (2 π)/5}],
   Table[
    2/(3 + Sqrt[5]) {Cos[t + π/5], Sin[t + π/5]}, {t, 0, 
    2 π, (2 π)/5}]
   ]]
  }]

I'm not certain about the scaling factor for the valleys, but it looks close enough.

Answer 3

You could also fill it with a disk. I'm hoping for a less manual answer anyway

Graphics[{Yellow, 
  Polygon[Table[{Cos[t], Sin[t]}, {t, 0, 4 \[Pi], (4 \[Pi])/5}]], 
  Disk[{0, 0}, 1/GoldenRatio^2]}]

Answer 4

Graphics[{Yellow, Polygon@
Table[(1 - (Sqrt[5] - 1)/2*Mod[i, 2])*{Cos[π/5 i], Sin[π/5 i]}, {i, 0, 9}]}]

I found a new way.

Answer 5

Graphics[{Yellow, 
  Polygon[Table[{Sin[t], Cos[t]}, {t, 0, 4 π, (4 π)/5}]], 
  Polygon[Table[1/2 (3 - Sqrt[5]) {Sin[t + Pi/5], Cos[t + Pi/5]},
{t, 0, 2 π, (2 π)/5}]]}]

Answer 6

Also:

 ListLinePlot[Table[{Cos@i, Sin@i}, {i, 0, 4 \[Pi], 4 \[Pi]/5}],
     PlotStyle -> None, Axes -> None, Filling -> 0, AspectRatio -> 1, 
     FillingStyle -> Yellow]