How can I completely remove the ListAnimate controls?

Question

I want to use ListAnimate to show an animation but I want to remove the slider and all of the buttons from the top and show the animation panel only. There is an AppearanceElements -> None option but it doesn't remove the slider and the other buttons. How can I remove all of the controls?

Answer 1

If you look at underlying code:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}]] // InputForm

at the end you'll find:

which leads to a trick:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}]] /. 
 HoldPattern[AppearanceElements -> _] -> (AppearanceElements -> None)

In the spirit of @Mr.Wizard comment you can also do something like:

ListAnimate[Table[Plot[Sin[n x], {x, 0, 10}], {n, 25}], 
  Paneled -> False] /. (AppearanceElements -> _) -> (AppearanceElements -> {})

which a bit changes things.

Answer 2

I don't know how to do that. Perhaps you are open to an alternative?

animate[list_List, rate_?Positive] := DynamicModule[{x = list},
  Dynamic[First[x = RotateLeft@x], UpdateInterval -> 1/rate, TrackedSymbols -> {}]]

list = Table[Plot[Sin[x + n], {x, 0, 3 Pi}], {n, 0, 2 Pi, Pi/20}];

animate[list, 15]

Answer 3

Since

ListAnimate generates a Manipulate object containing an Animator (docs)

With explicit lists as input, say,

 list = Table[Plot[Sin[x + n], {x, 0, 3 Pi}], {n, 0, 2 Pi, Pi/20}];

the animation produced by ListAnimate[list...] can also be produced using Manipulate or Animator specifying the Animator option settings directly (instead of post-processing the Manipulate object generated by ListAnimate).

Manipulate[list[[k]], {{k, 1, ""}, 1, Length[list], 1,
      ControlType -> Animator, AnimationRate -> 15, 
      AnimationRunning -> True, AppearanceElements -> {}},
  AppearanceElements -> None, Paneled -> False]

or

DynamicModule[{j},
  Column[{Animator[Dynamic[j], {1, 10, 1}, 15, 
       AnimationRunning -> True, AppearanceElements -> None], 
  Dynamic[list[[j]]]}]]