Using variables in function names

Question

I want to make a list of plots and my functions are named C1, C2... Cn.

The command I wish to execute is:

Table[Plot[Cn[t], {t, 0, 1}], {n, 1,6}]]

which obviously doesn't work. How is the equivalent of the above done in Mathematica?

EDIT: Thanks for the answers. Here is what it looks like:

Answer 1

You can also use ToExpression to join the index n to your base function name, C, as in the following example:

C1 = Sin[x];
C2 = Cos[x];
C3 = Tan[x];
Table[Plot[Evaluate[ToExpression["C" <> ToString@i]], {x, -π, π}], {i, 3}]

Answer 2

How about something like:

Plot[#, {t, 0, 1}] & /@ 
 (ToExpression /@ 
   Table["C" <> ToString[n] <> "[t]", {n, 1, 4}])

Edit With a form closer to your original code:

Table[Plot[ToExpression["C" <> ToString[n] <> "[t]"], {t, 0, 1}],
 {n, 1, 4}]

For example, with:

C1[t_] := t
C2[t_] := t^2
C3[t_] := t^3
C4[t_] := t^4

Using either of the two solutions here gives:

Answer 3

Alternatively, you may define indexed family of functions like c[1],...,c[n]. Indices do not have to be contiguous, as you can get them all from the symbol definition. So if you define

c[1] = Sin;
c[2] = Cos;
c[3][x_] := Cos[x]^2;

you can do the plotting by iterating the index

Table[Plot[c[i][x], {x, -Pi, Pi}], {i, 3}]

You can also iterate over all defined indices in a general way:

Plot[c[#][x], {x, -Pi, Pi}] & /@ 
   Union[SubValues[c][[All, 1, 1, 0, 1]], 
        DownValues[c][[All, 1, 1, 1]]]

You may also define a function to help with such an iteration, to hide the ugliness of index scavenging:

AllFunIndices[sym_Symbol] := 
  Union[SubValues[sym][[All, 1, 1, 0, 1]], 
       DownValues[sym][[All, 1, 1, 1]]];
SetAttributes[AllFunIndices, HoldAll]

and then the plotting code over indices becomes much more transparent

Plot[c[#][x], {x, -Pi, Pi}] & /@ AllFunIndices[c]

Answer 4

You could define your functions like this:

Subscript[s, 1][t_] = Sin[t];
Subscript[s, 2][t_] = Cos[t];

And then plot using:

Plot[Evaluate[Table[Subscript[s, n][x], {n, 2}]], {x, -Pi, Pi}]

Just overlooked: This will create one Plot with all plots in it. The way your code snippet is written it looks as if you try to get each graph in its own plot in which case you have to use

Table[Plot[Subscript[s, n][x], {x, -Pi, Pi}], {n, 2}]

Answer 5

This is the perfect time to use With to handle the creation of the variable name. For instance,

C1[t_] := Tanh[t];
C2[t_] := Sinh[t];
C3[t_] := Cosh[t];
GraphicsRow@Table[
 With[{f = ToExpression["C" <> ToString[i]]}, 
   Plot[f[t], {t, -1, 1}]], 
 {i, 3}]

gives

By using With to create the function name outside of Plot it is only executed once, not for every point.