Multi-column table layout the right way

Question

How do I create book-like multi-column table formatting for a long, narrow tables in a preferably elegant way? Should I be thinking of stylesheets, instead of formatting? I guess this is a solved problem, after all.

Row expression below is my own, feeble attempt to solve the problem. Although output is reasonably OK, I detest many details on the implementation; for instance, the magic constant 1.2 needed to make columns evenly tall.

Row[Pane[
      Grid[#, Frame -> All, ItemSize -> {Automatic, 1.2}, 
       ItemStyle -> FontFamily -> "Times", 
       Alignment -> {{Right, Left}, Center}],
      ImageMargins -> 2] &
    /@ Partition[#1, #2]] &[
 {Round[#[[1]]], CityData[#[[2]], "FullName"]} &
  /@ ({GeoDistance[$GeoLocation, CityData[#, "Coordinates"]]/
        1000, #} & 
     /@ CityData[]~Select~(CityData[#, "Population"] >= 100000 &))
   ~SortBy~First
   ~Take~(3*20),
 20]

Answer 1

Perhaps I am missing the subtlety of your formatting needs but I think you can make this a lot simpler.

With your two column table as dat try:

Grid[
  dat ~Partition~ 20 ~Flatten~ {{2}, {1, 3}},
  Dividers -> {{All, {3 -> Thick, 5 -> Thick}}, All},
  Alignment -> {{{Right, Left}}, Center},
  Spacings -> {{{1, 0.5}}},
  BaseStyle -> {FontFamily -> "Times"}
]

If the separation between pairs of columns is desired you might use:

Row[
 Grid[#,
    Dividers -> All,
    Alignment -> {{Right, Left}},
    Spacings -> {{{1, 0.5}}},
    BaseStyle -> {FontFamily -> "Times"}
 ] & /@
  dat ~Partition~ 20
]

---

Third try:

newdat = Flatten @ Riffle[#, Item[Spacer[0], Frame -> {False, True, False, True}]] & /@ 
          Transpose[dat ~Partition~ 20];

Grid[
  newdat,
  Dividers -> All,
  Alignment -> {{{Right, Left}}, Center},
  Spacings -> {{{1, 0.5, 0.5}}},
  BaseStyle -> {FontFamily -> "Times"}
]

Here is the inverse of the above (output looks the same); it may be more convenient sometimes.

newdat = Flatten @ Riffle[#, Spacer[0]] & /@ 
   Transpose[Map[Item[#, Frame -> All] &, dat, {2}] ~Partition~ 20];

Grid[
  newdat,
  Alignment -> {{{Right, Left}}, Center},
  Spacings -> {{{1, 0.5, 0.5}}},
  BaseStyle -> {FontFamily -> "Times"}
]