# How do I introduce a new variable in a trigonometric equation?

I have the trigonometric equation \begin{equation*} \sin^8 x + 2\cos^8 x -\dfrac{1}{2}\cos^2 2x + 4\sin^2 x= 0. \end{equation*} By putting $t = \cos 2x$, I have \begin{equation*} \dfrac{3}{16} t^4+ \dfrac{1}{4}t^3 + \dfrac{5}{8}t^2 -\dfrac{7}{4}t + \dfrac{35}{16} = 0. \end{equation*} How do I tell Mathematica to do that? Mathematica code is

Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0

-
If you supply your terms in Mathematica syntax as well, that would make working with them much more comfortable. –  Yves Klett Sep 27 '12 at 16:13
With Maple, I used the following code restart; sort(simplify(algsubs(1-sin(x)^2=cos(x)^2, sin(x)^8+ 2*cos(x)^8 -1/2*cos(2*x)^2 + 4*sin(x)^2), {expand(cos(2*x))=t})); –  minthao_2011 Sep 27 '12 at 16:17
I meant: Please format your (LaTeX) expressions in Mathematica syntax so we can copy and paste easily. –  Yves Klett Sep 27 '12 at 16:32

You can use TrigExpand to expand all trigonometric functions to fundamental forms and then Eliminate solves the rest

eq1 = Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0;
eq2 = t == Cos[2 x]

Eliminate[TrigExpand[{eq1, eq2}], x]

-

One way to do this is:

Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0 /.
Solve[t == Cos[2 x], x] //FullSimplify // Expand // Union // Column // TraditionalForm


This will also work with more complex substitutions (for example t == Cos[x^2 - 1] ) when you can get multiple results:

Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0 /.
Solve[t == Cos[x^2 - 1], x]//FullSimplify//Expand//Union //Column // TraditionalForm


-

A bit different approach :

Simplify @ TrigReduce[ Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0
/. Solve[ t == Cos[2 x], x, InverseFunctions -> True][[1]]]

35 + 10 t^2 + 4 t^3 + 3 t^4 == 28 t


or using Eliminate :

Eliminate[ TrigToExp[{ Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0,
t == Cos[2 x]}], x, InverseFunctions -> True] //

3 t^4 + 4 t^3 + 10 t^2 - 28 t == -35

-

First plot the trigonometric equation:

Plot[Sin[x]^8 + 2 Cos[x]^8 - 1/2 Cos[2 x]^2 + 4 Sin[x]^2 == 0, {x, 0, 2 Pi}]


You will see that there are no (real) solutions. Is this what you expect?

-
No. I only want as I asked. –  minthao_2011 Oct 4 '12 at 2:43