Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I'm writing a Monte Carlo simulation. I'm using a Do loop to create the different simulations, iterating over different SeedRandom[] parameters in my pseudorandom number generator. I'm trying to formulate it as a function that returns a list of correlations that I can then manipulate.

I expect there is a very simple solution, but I have to admit that I'm pretty new to Mathematica so I'm having problems. The Mathematica documentation seems to conveniently dodge this issue whenever it comes up! This might be a little complicated, so I'll explain what my code does first, then I'll describe the problem precisely.

First I make a list with the parameters of each of my random variables (I want them to have different means):

varparams = Table[i, {i, 0.1, 0.9, 0.1}];

Then I define my random variables:

var[i_]:=RandomChoice[{varparams[[i]],1-varparams[[i]]}->{1,0},10]

(I'm generating [for argument's sake] a set of 10 values for each run of the simulation).

Now, I define the function that iterates over different SeedRandom[] values, so as to generate different data sets. I want to calculate a list of correlations:

corrlist = {};
corrcheck[i_, j_, n_] := Do[
  SeedRandom[k];
  AppendTo[corrlist, Correlation[var[i], var[j]]];
  , {k, n}]

(n is the number of different runs of the simulation).

Now this sort of works, in the sense that I can run corrcheck[i,j,n] and then work with the corrlist that is produced, but what I want is for corrcheck[i,j,n] itself to be a list, so that I can make tables and other manipulations of corrcheck for different values of i and j. I hope this makes sense. To reiterate: I want the function corrcheck, which consists of a Do loop, to produce a unique list for each set of i,j,n, so that I can do things like:

Table[corrcheck[i,j,100],{i,10},{j,10}]

and manipulations thereof.

The answer has to be obvious. I just can't see it!

Thank you very much in advance.

share|improve this question
    
Something like corrcheck[i_, j_, n_] := Table[BlockRandom[SeedRandom[k]; Correlation[var[i], var[j]]], {k, n}] then? –  J. M. Sep 27 '12 at 14:10
    
Wow. I thought it would be easy, but that's really obvious now that I think about it. Thanks! I don't know why I had the idea that a Do[] loop was necessary. –  Ooku Sep 27 '12 at 14:13
    
I'll probably accept that as an answer, if you care to submit it - I can't imagine a simpler solution. –  Ooku Sep 27 '12 at 14:16
    
Tell me if I understood correctly: you want corrcheck[i_, j_, n_] to build a list with n simulations of correlation (10 samples each) between 2 independent bernoullis with weights defined by i and j, and you want that function to always return the same output for the same i,j,n ? –  Rojo Sep 27 '12 at 14:16
3  
@Ooku Do loops are not necessarily bad; in fact, their syntax is identical to Table - a functional stalwort. When a loop is necessary, Do is typically the way to go. The biggest issue with your code is the AppendTo command; look into useing Reap and Sow, rather than Append or AppendTo. –  Mark McClure Sep 27 '12 at 14:45

1 Answer 1

up vote 9 down vote accepted

This seems to be what you want:

corrcheck[i_, j_, n_, opts___] := Table[BlockRandom[
   SeedRandom[k, FilterRules[{opts}, Method]];
   Correlation[var[i], var[j]]], {k, n}]

The additional optional argument allows you to change the algorithm used behind the pseudorandom number generator; you can thus do either a call like corrcheck[7, 10, 100] if you're happy with the defaults, or corrcheck[7, 10, 100, Method -> "MersenneTwister"] if you want to fool around with the Mersenne Twister.

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.