Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I have the following equation given:

$$ (26-x)\cdot\sqrt{5x-1} -(13x+14)\cdot\sqrt{5-2x} + 12\sqrt{(5x-1)\cdot(5-2x) }= 18x+32. $$

In order to solve it, I want to substitute $t = \sqrt{5x - 1}-\sqrt{5-2x}$. This cannot be done directly but with this step the equation could be transformed in the form $(t-2)^3 = 0$, which can be solved easily.

Is it possible to make this substitution with Mathematica? The only thing I have achieved is to solve it directly with

Solve[(26 - x)*Sqrt[5*x - 1] - (13*x + 14)*Sqrt[5 - 2*x] + 
      12*Sqrt[(5*x - 1)*(5 - 2*x)] == 18*x + 32]
share|improve this question

1 Answer 1

up vote 10 down vote accepted

A standard approach for this kind of task uses Eliminate. It works nicely with polynomial equations, and even though neither this transformation : $\;\sqrt{5x - 1}-\sqrt{5-2x} \rightarrow t \quad$ nor the original equation : $ (26-x)\sqrt{5x-1} -(13x+14)\sqrt{5-2x} + 12\sqrt{(5x-1)(5-2x) }= 18x+32\quad$ are of polynomial types, nevertheless we can make some tricks to get exactly $\;(t-2)^3 = 0$.

Defining

f[x_] := (26-x) Sqrt[5x-1] - (13x+14) Sqrt[5-2x] + 12 Sqrt[(5x-1)(5-2x)] - 18x - 32

terms like : $\sqrt{(5x-1)(5-2x)}\;$ should be PowerExpand'ed in order to get the lowest possible order of resulting polynomials (otherwise we would get a ninth order polynomial):

Eliminate[{ f[x] == 0 // PowerExpand, Sqrt[5x-1] - Sqrt[5-2x] == t}, x]
 12 t - 6 t^2 + t^3 == 8

If we didn't play with PowerExpand we would use another definition of function $f$ yielding effectively the same result :

f1[x_] := (26-x) Sqrt[5x-1] - (13x+14) Sqrt[5-2x] + 12 Sqrt[(5x-1)] Sqrt[5-2x] - 18x - 32

Eliminate[{ f1[x] == 0, Sqrt[5x-1] - Sqrt[5-2x] == t}, x]

Now we rewrite the equation we've got -8 + 12 t - 6 t^2 + t^3 == 0 in the following form :

TraditionalForm[-8 + 12 t - 6 t^2 + t^3 == 0 // Factor]

enter image description here

And this is indeed equivalent to our orignial function f[x] :

(t-2)^3 == f[x] /.t-> Sqrt[5x-1] - Sqrt[5-2x] // FullSimplify
 True

Edit

It is remarkable that f being rather a complicated (complex also for real arguments) function has only one simple root :

Reduce[ f[x] == 0, x]
x == 2

which implies t == 2. To make this result more understandable we can plot the contours of f in a complex domain :

GraphicsRow[ Table[ Show[
    ContourPlot @@@ { { g[f[x + I y]], {x, -2, 6}, {y, -4, 4}, Contours -> 37,
                        RegionFunction -> Function[{x, y}, 60 > g[f[x + I y]] > -60],
                        PlotLabel -> Style[ g[HoldForm @ f[x + I y]], Blue, 15],
                        ColorFunction -> "DeepSeaColors"},
                      { Re @ f[x + I y] == 0, {x, -2, 6}, {y, -4, 4},
                                              ContourStyle -> {Red, Thick}},
                      { Im @ f[x + I y] == 0, {x, -2, 6}, {y, -4, 4}, 
                                              ContourStyle -> {Cyan, Thick}} }, 
    Graphics[{ Thickness[0.01], Darker @ Green, Line[{{0.2, 0}, {2.5, 0}}]}]],

                    {g, {Re, Im, Abs}}]]

enter image description here

The color curves denote the following sets of points z in the complex plane

  • red ; where: Re[ f[z]] == 0
  • cyan ; where: Im[ f[z]] == 0
  • green ; the set of z where Im[ f[z]] == 0 restricted to the real domain.

One can easily see that these curves cross only at z == {2,0}.

We complement the plots of the function f restricting to the real domain only (here the green line denotes the region where the imaginary part vanishes):

GraphicsRow[
    Plot[{ Re @ f[x], Im @ f[x]}, {x, ##}, AxesOrigin -> {0, 0}, PlotRange -> Automatic,
         PlotStyle -> { Thick, Thickness[0.008]}, AspectRatio -> 1.1, 
         Epilog -> { { Thickness[0.01], Darker @ Green, Line[{{0.2, 0}, {2.5, 0}}]},
                     { PointSize[0.023], Red, Point[{2, 0}]}}] &
    @@@ {{-3, 3}, {-.1, 3.5}, {0.7, 3}}]

enter image description here

share|improve this answer
    
Thank you very much. –  minthao_2011 Sep 22 '12 at 16:12
1  
This is a solution by hand with the help of Mathematica. Put $t=\sqrt{5x-1}-\sqrt{5-2x}.$ We have $$t^2=3x+4-2\sqrt{(5x-1)( 5-2x)}$$ And $$t^3=(14-x)\sqrt{5x-1}-(13x+2)\sqrt{5-2x}.$$ Put $$f(x)=(26-x)\sqrt{5x-1}-(13x+14)\sqrt{5-2x}+12\sqrt{5x-1)( 5-2x)}-(18x+32)$$ With the command Simplify in Mathematica, we have $[(t-2)^3 - f(x)] = 0.$ That why, my question, I wrote "put" $t=\sqrt{5x-1}-\sqrt{5-2x}.$ But I can not write the code as Artes. –  minthao_2011 Sep 22 '12 at 23:10
    
thank you very much. –  minthao_2011 Sep 27 '12 at 15:46
    
@minthao_2011 I added plots of the function f in order to make the problem easier to understand. I had to try a few ways to tackle this issue and this is not a simple problem in general. I find your question really interesting and I hope you'll gain more upvotes for it. –  Artes Sep 27 '12 at 15:56
    
This method can be use to solve the system of the equations. For example \begin{equation*} \begin{cases} x^3 + y^3 = 2,\\ x^2 + y^2 -3xy=-1. \end{cases} \end{equation*} f[x_, y_] := x^3 + y^3 Eliminate[{f[x, y] == 2 // PowerExpand, x + y == S, x*y == P}, {x, y}] g[x_, y_] := x^2 + y^2 - 3*x*y Eliminate[{g[x, y] == -1 // PowerExpand, x + y == S, x*y == P}, {x, y}] –  minthao_2011 Oct 6 '12 at 14:19

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.