How do I place a graphical marker (box, circle, ...) in a MatrixPlot?

Question

I'm trying to locate minima / maxima in matrices on a heat map. So I have my 2D matrix and did a MatrixPlot,

and I can find the position of the smallest value.

My question: how do I place a graphical marker at that position? Like a box to outline field (7,6)?

Completely stumped.

Answer 1

To position the highlight rectangle properly, the array position of the highlighted value must be converted into a graphics coordinate. For a data array of $n$ rows, to highlight the value at row $i$ and column $j$ requires the bottom left corner of the rectangle to be placed at graphics coordinate $\{j-1, n-i\}$

Example:

highlight[data_, patt_, directives_] :=
 {FaceForm[None], EdgeForm[directives],
  Rectangle[{#2 - 1, Length[data] - #1}] & @@@ Position[data, patt]}

data = N@Table[x^2 + y^2, {x, -4, 3, 6/11}, {y, -4, 3, 6/11}];

MatrixPlot[data, Epilog -> {
   highlight[data, Min[data], {Thick, Red}],
   highlight[data, x_ /; 5 < x < 6, {Blue, Dashed}]
   }]

Answer 2

This is an addition to Simon's excellent answer. For large matrices, MatrixPlot applies some automatic down-sampling which messes up the coordinates.

Small matrix:

m1 = SparseArray[{i_, i_} -> 1, {100, 100}];
mp1 = MatrixPlot@m1;
marker1 = Rectangle[{0, 60}, {40, 100}];
style = Graphics[{FaceForm[None], EdgeForm[Dashed], #}] &;

Show[mp1, style@marker1]

Large matrix:

m2 = SparseArray[{i_, i_} -> 1, {1000, 1000}];
mp2 = MatrixPlot@m2;
marker2 = Rectangle[{0, 600}, {400, 1000}];

Show[mp2, style@marker2]

One can extract the scale from the second argument of the plot's Raster and correct the marker coordinates accordingly:

scaleToRaster[coords_, dims_, plot_] := coords * plot[[1, 2, 2]] / Reverse@dims;

Show[mp2, style[scaleToRaster[#, Dimensions@m2, mp2]& /@ marker2]]