Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

Sign up
Here's how it works:
  1. Anybody can ask a question
  2. Anybody can answer
  3. The best answers are voted up and rise to the top

I have a series of Manipulate activities in a single notebook I am preparing for a presentation tomorrow. After the fourth one moves so that it is partially in view, I get the blinking black cell. I tried TrackedSymbols:>{k} but that did not work. Any thoughts? The sequence of Manipulates follows. They are all in separate input cells.

Manipulate[
 Plot[Sin[x - k], {x, -2 \[Pi], 2 \[Pi]}],
 {{k, 0}, -2 \[Pi], 2 \[Pi], Appearance -> "Labeled"}]

Manipulate[
 Plot[{Sin[x], Sin[x - k]}, {x, -2 \[Pi], 2 \[Pi]}],
 {{k, 0}, -2 \[Pi], 2 \[Pi], Appearance -> "Labeled"}]

Manipulate[
 Plot[{Sin[x], Sin[x - k]}, {x, -2 \[Pi], 2 \[Pi]},
  GridLines -> Automatic],
 {{k, 0}, -2 \[Pi], 2 \[Pi], Appearance -> "Labeled"}]

Manipulate[
 label = TraditionalForm[x - k];
 Plot[{Sin[x], Sin[x - k]}, {x, -2 \[Pi], 2 \[Pi]},
  GridLines -> Automatic,
  PlotLabel -> 
   Pane[StringForm["y = f(``)", label], 200, Alignment -> Center]
  ],
 {{k, 0}, -2 \[Pi], 2 \[Pi], Appearance -> "Labeled"}]

Manipulate[
 label = TraditionalForm[x - k];
 Plot[{Sin[x], Sin[x - k]}, {x, -6, 6},
  GridLines -> Automatic,
  PlotLabel -> 
   Pane[StringForm["y = f(``)", label], 200, Alignment -> Center]
  ],
 {{k, 0}, -6, 6, 1, Appearance -> "Labeled"}]

Manipulate[
 label = TraditionalForm[x - k];
 Plot[{Sin[x], Sin[x - k]}, {x, -6, 6},
  GridLines -> {Range[-6, 6, 1], Automatic},
  PlotLabel -> 
   Pane[StringForm["y = f(``)", label], 200, Alignment -> Center]
  ],
 {{k, 0}, -6, 6, 1, Appearance -> "Labeled"}]
share|improve this question
up vote 8 down vote accepted

Keep all your symbols localised to the Manipulate by adding {x, None}, {label, None} at the end. Example:

Manipulate[label = TraditionalForm[x - k];
 Plot[{Sin[x], Sin[x - k]}, {x, -6, 6}, GridLines -> Automatic, 
  PlotLabel -> 
   Pane[StringForm["y = f(``)", label], 200, 
    Alignment -> Center]], {{k, 0}, -6, 6, 1, 
  Appearance -> "Labeled"}, {x, None}, {label, None}]

This way each Manipulate is entirely self contained rather than having global variables shared across each Manipulate

share|improve this answer
    
Nice answer. Thanks. – David Feb 9 at 6:13

In addition to what Mike Honeychurch advised one further reason for problems may be that many dynamic object working at once may be too difficult for your computer. Only those Manipulates are active that are actually on the screen. However, these also may be too much in some cases. I always try to have different Manipulatestatements on different pages of my presentation, if possible.

share|improve this answer

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.