Marking points of intersection between two curves

Question

I'm trying to illustrate the solutions numerically and graphically for an equation such as Tan[x] == x. I think I did everything ok except I wanted to mark each intersection between Tan[x] and x.

Does anyone know how such a thing can be done?

Answer 1

f[x_] := Tan[x]
g[x_] := x

sol = x /. NSolve[g[x] == f[x] && -10 < x < 10, x]
Show[Plot[    {f[x], g[x]}, {x, -10, 10}], 
     ListPlot[{#, g[#]} & /@ sol, PlotStyle -> PointSize[Large]]]

Edit

A little bit more sophisticated. Using the comments by @Oleksandr and @JM below. For the strange Exclusions specification I use below, see my answer here

f[x_] := Tan[x]
g[x_] := x

sol = x /. NSolve[g[x] == f[x] && -10 < x < 10, x]
Framed@Show[
  ListPlot[{#, g[#]} & /@ sol, PlotStyle -> PointSize[Large], Ticks -> {Range[-5, 5] Pi}],
      Plot[{f[x], g[x]}, {x, -10, 10}, Exclusions -> {True, f[x] == 1}]]

Answer 2

You can also use MeshFunctions:

  Plot[{Cos[x], x Sin[x]}, {x, -3 Pi, 3 Pi}, 
     MeshFunctions -> {(Cos[#] - # Sin[#]) &}, Mesh -> {{0}}, 
     MeshStyle -> Directive[Red, PointSize[Large]]]

Update: Dealing with Tan[x] using Exclusions

Plot[{Tan[x], x Sin[x]}, {x, -3 Pi, 3 Pi}, 
   MeshFunctions -> {(Tan[#] - # Sin[#]) &}, Mesh -> {{0}}, 
   MeshStyle -> Directive[Red, PointSize[Large]], 
   Exclusions -> Range[-5 Pi/2, 5 Pi/2, Pi]]
   (* or Exclusions -> (Cos[x] == 0) *)

Update 2: Using just Mesh and MeshStyle:

points = NSolve[Tan[x] == x Sin[x] && -3 Pi < x < 3 Pi, x][[All, 1, 2]];
Plot[{Tan[x], x Sin[x]}, {x, -3 Pi, 3 Pi},
  Mesh -> {points},
  MeshStyle -> {Directive[Red, PointSize[Large]]},
  Exclusions -> Range[-5 Pi/2, 5 Pi/2, Pi]]
(* same picture as above *)