Take the 2-minute tour ×
Mathematica Stack Exchange is a question and answer site for users of Mathematica. It's 100% free, no registration required.

I would like to apply some complex valued function to some region in the plane, say, a circle of radius $R$ centred at $k$.

How can I do this?

share|improve this question
1  
Related : Plotting complex Sine mathematica.stackexchange.com/questions/6862/… –  Artes Sep 3 '12 at 21:16

4 Answers 4

up vote 20 down vote accepted

Under the interpretation of OP's question as

How do I apply the transformation $w=f(z)$ to a region (e.g. a disk) in the complex plane?

I'd say ParametricPlot[] (which now incorporates the functionality from the old Graphics`ComplexMap` package) would be what you can use:

With[{f = # + 1/# &, center = 1/3 + 3 I/2, radius = 4/3}, 
 ParametricPlot[
       Through[{Re, Im}[f[center + r Exp[I θ]]]], {r, 0, radius}, {θ, -π, π},
               PlotPoints -> 45, PlotRange -> All]]

transformation of a disk

share|improve this answer
    
That is awesome!!! –  Fawkes5 Sep 4 '12 at 3:23

There are many ways to represent visually a complex-valued function of a complex variable. Here's another one. (Instead of superimposing the plots of real and imaginary parts, you could make a Row or GraphicsRow of them.

Plot3D[Through[{Re, Im}[ArcSin[x + y I]]], {x, -Pi, Pi}, {y, -Pi, Pi},
      RegionFunction -> Function[{x, y, z}, x^2 + y^2 <= Pi^2], 
      MeshFunctions -> {Re[Sqrt[#1 + I #2]] &, Im[Sqrt[#1 + I #2]] &},
      BoxRatios -> {1,1,0.7}]

Real & imaginary parts of arcsin on disk

share|improve this answer

I thought the question was to apply a translation to the circle.

Including the option for radius size and location of center of circle:

f[radius_, {x1_, y1_}] := 
DensityPlot[Sin[x]*Sin[y], {x, -12, 12}, {y, -12, 12}, 
RegionFunction -> Function[{x, y}, (x - x1)^2 + (y - y1)^2 < radius^2],
ColorFunction -> "SunsetColors", GridLines -> {{x1}, {y1}}]

f[2, {5, -3}]

Making this interactive,

Manipulate[ DensityPlot[Sin[x]*Sin[y], {x, -12, 12}, {y, -12, 12}, 
 RegionFunction -> Function[{x, y}, (x - x1)^2 + (y - y1)^2 < radius^2],
 ColorFunction -> "SunsetColors", GridLines -> {{x1}, {y1}}, 
 PlotRange -> 15],{{x1, 0}, -10, 10},{{y1, 0}, -10, 10, Slider},{{radius, 1}, 0, 4, Slider}]

sliders

share|improve this answer
    
That is wonderful, thank you!!! –  Fawkes5 Sep 4 '12 at 3:24

Use RegionFunction, like so:

DensityPlot[Sin[3*x]*Cos[4*y], {x, -2, 2}, {y, -2, 2}, 
 RegionFunction -> Function[{x, y}, x^2 + y^2 < 4]]

enter image description here

share|improve this answer
    
Also awesome!! Thanks! –  Fawkes5 Sep 4 '12 at 3:26

Your Answer

 
discard

By posting your answer, you agree to the privacy policy and terms of service.

Not the answer you're looking for? Browse other questions tagged or ask your own question.