Nested definition: How can I define a function with a passed-in expression?

Question

Here's a simplified version of what I'm trying to do:

SetAttributes[def,HoldFirst]
def[s_Symbol,v_]:=(s[x_]:=v)
def[f,x^2]
f[3] (* Expected result: 9 *)
(*
==> x^2
*)
?f (* Expected result: f[x_] := x^2 *)
(*
Global`f

f[x$_] := x^2
*)

Obviously the x in the x_ pattern gets replaced by x$. Is there a way I can prevent that? That is, from calling def[f,x^2] I want to result the definition f[x_] := x^2. I don't of course care about the name of the variable, so if the resulting function definition reads f[x$_] := x$^2 I'm fine with that, too.

I tried def[s_Symbol,v_]:=With[{x$=x}, s[x_]:=v], def[s_Symbol,v_]:=With[{x=x$},s[x_]:=v], def[s_Symbol,v_]:=(s[x_]:=v)/.x:>x$ and def[s_Symbol,v_]:=(s[x_]:=v)/.x$:>x, but neither worked.

Answer 1

With your proposed definition style, the user of that function def has to know that v could/should/must depend on x for this to work; x really should be an argument of def. Perhaps something like this were better suited.

ClearAll[def]
ClearAll[f]
(*SetAttributes[def,HoldFirst]*)

def[s_Symbol, v_, vars_List] := 
 With[{h = s @@ (Pattern[#, Blank[]] & /@ vars)}, (h := v)]
def[f, x^2, {x}]

f[3]
(* 9 *)

Answer 2

Try for example

SetAttributes[def, HoldAll]
def[s_Symbol, v_] := Function[Null, s[x_] := #, HoldFirst][v]

Unnamed functions just don't care :)

Other alternatives that should also work (but I would use the previous approach)

def[s_Symbol, v_] := Identity[SetDelayed][HoldPattern@s[x_], v];
def[s_Symbol, v_] := Unevaluated[s[x_] := "Hello"] /. "Hello" -> v