Simplify equations with pattern assumptions

Question

When simplifying an expression using Simplify[expr, assumptions], the assumptions has to be explicit. Is it possible to simplify an expression with pattern assumptions?

(TransformationFunctions can satisfy some of the needs, but it is not always functional as in the following examples.)

For example

psimp[Sqrt[a[t]^2], a[m_] > 0]

a[t]

psimp[f[x] (1 + a) (1 + b) == 0, f[a_] != 0]

(1 + a) (1 + b) == 0

psimp[(d[t] + b[t] + c[t])^2 + (d[m] + b[m] + c[m])^3 + a[n] + x[n] //
   Expand, {d[f_] + b[f_] + c[f_] == a[f], a[n] + x[n] == s}]

s + a[m]^3 + a[t]^2

psimp[g[x, y]*Derivative[0, 1][f][x, y] + f[x, y]*Derivative[0, 1][g][x, y], 
 (g_)[x_, y_]*Derivative[0, 1][f_][x_, y_] + (f_)[x_, y_]*Derivative[0, 1][g_][x_, y_] == Defer[D[f[x, y]*g[x, y], y]]]

D[f[x, y]*g[x, y], y]

Answer 1

This can be accomplished by dynamically analyzing the expression and generating the explicit assumptions from the given assumptions pattern.

ClearAll[psimp, psimpStep, ptn2explicit];

ptn2explicit[expr_, pattern_List, RHS_] := 
 With[{cases = Cases[expr, #, {0,Infinity}, Heads -> True] & /@ pattern, 
   ruleLHS = {___, #, ___} & /@ pattern, 
   ruleRHS = pattern /. Verbatim[Pattern][arg_, ___] :> arg},
  MapThread[Verbatim[#1] -> #2 &, {pattern~Append~RHS, #}] & /@ 
   ReplaceList[cases, ruleLHS :> (ruleRHS~Append~RHS)]]

psimp[expr_, cond_] := psimp[expr, {cond}];

psimpStep[expr_, cond_List] := 
 Module[{LHS, RHS, explicitCond, \[UnderBracket], operator, opList, count},
  operator = Equal | Unequal | Greater | Less | GreaterEqual | LessEqual | Element;
  LHS = Cases[cond, (l_~operator~r_) :> l];
  RHS = Cases[cond, (l_~(o : operator)~r_) :> 
     If[o === Equal, \[UnderBracket][][][]@r, r]];
  opList = Cases[cond, (l_~(o : operator)~r_) :> o];
  explicitCond = And @@ Union@
     Flatten[#1~#2~#3 /. ptn2explicit[expr, Variables@#1, #3] & @@@ 
       Transpose[{LHS, opList, RHS}]]; 
  count[e_] := LeafCount[e] - Count[e, \[UnderBracket][][][][_]];
  Simplify[expr, explicitCond, 
    ComplexityFunction -> count] /. \[UnderBracket][][][][x_] :> x]

psimp[expr_, cond_List] := FixedPoint[psimpStep[#, cond] &, expr]

A few explanations are in order here:

(1) Function ptn2explicit generates a list of rules to convert the patterns in expr into explicit expressions. For example,

ptn2explicit[a[t] + b[t] + a[m] + b[m] + c[m], {a[f_], b[f_]}, d[f]]

{{Verbatim[a[f_]] -> a[m], Verbatim[b[f_]] -> b[m], Verbatim[d[f]] -> d[m]}, {Verbatim[a[f_]] -> a[t], Verbatim[b[f_]] -> b[t], Verbatim[d[f]] -> d[t]}}

The ptn2explicit function is a modified version of @halirutan's answer in How to do Cases with multiple related patterns?. (BTW: everybody complains the question in this link was not clear. I guess you know what I want to do in case you also read this post ^_^)

(2) A strange symbol \[UnderBracket] is used here. Because this is the named and visible symbol with greatest lexical order (at least among the first 10^4). As noticed in Why does Simplify ignore an assumption? and references therein, we need to use symbols with greater lexical order for some rules to take effect.

The SubValues \[UnderBracket][][][] is to further reduce the lexical order of this symbol. Otherwise Derivative[__][__][__] has lower order. This particular subvalued one is not the absolute lowest lexical ordered one, but would be enough for most cases.

(3) After simplification, the new expression may contain new symbols that matches the given assumptions pattern. Thus we perform a FixedPoint, until the result stabilizes.

(4) There is a limitation that one has to give names to each patterns in the assumption. For example, psimp[Sqrt[a[t]^2], a[_] > 0] doesn't work but psimp[Sqrt[a[t]^2], a[m_] > 0] works.