Manipulating curl and div of a vector in spherical coordinates

Question

I'm trying to show that an E field satisfies the two Maxwell equations: $\mathsf{Curl}[E]=-dB/dt$ and $\mathsf{Curl}[B]=(w/k)^2 dE/dt$

I define

$\qquad e_o(\text{t$\_$})\;\mathsf{:=}\;\left\{0,0,\frac{(A \sin (\theta )) \left(\cos (k r-t \omega )-\frac{\sin (k r-t \omega )}{k r}\right)}{r}\right\}$

Then

$\qquad B(\text{t$\_$})\;\mathsf{:=}\;\int_0^t \mathsf{Curl}\left[e_o(t)\right] \, dt$

Now I want to show that

$\qquad e_1(\text{t$\_$})\;\mathsf{:=}\;\int_0^t \left(\frac{\omega }{k}\right)^2 \mathsf{Curl}[B(t)] \, dt$

is equivalent to $e_o$

but the terms don't actually seem to be equivalent and FullSimplify doesn't seem to work right. I'm not sure if/how I am supposed to put constraints the constants k and w.

Here is my actual input text:

Subscript[E, o][r_, θ_, ϕ_] := 
  {0, 0, (A Sin[θ])/r (Cos[k r - ω t] - Sin[k r - ω t]/(k r))}

Div[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"]

0

Curl[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"]

{(2 A Cos[θ] (Cos[k r - t ω] - Sin[k r - t ω]/(k r)))/r^2, 
  -((A Sin[θ] (-(Cos[k r - t ω]/r) - k Sin[k r - t ω] + Sin[k r - t ω]/(k r^2)))/r), 
  0}

B[r_, θ_, ϕ_] := 
  -Integrate[Curl[Subscript[E, o][r, θ, ϕ], {r, θ, ϕ}, "Spherical"], {t, 0, t}]

FullSimplify[B[r, θ, ϕ]]

{(4 A Cos[θ] Sin[(t ω)/2] (-k r Cos[k r - (t ω)/2] + Sin[k r - (t ω)/2]))/(k r^3 ω), 
 -((2 A Sin[θ] Sin[(t ω)/2] (k r Cos[k r - (t ω)/2] + (-1 + k^2 r^2) Sin[k r - (t ω)/2]))/(k r^3 ω)), 
  0}

Simplify[Div[B[r, θ, ϕ], {r, θ, ϕ}, "Spherical"]]

0

Subscript[E, 1] := 
  Integrate[(ω/k)^2 Curl[B[r, θ, ϕ], {r, θ, ϕ}, "Spherical"], {t, 0, t}]

FullSimplify[Part[Subscript[E, 1], 3] == Part[Subscript[E, o][r, θ, ϕ], 3]]

(A ((k r + t ω) Cos[k r] + (-1 + k r t ω) Sin[k r]) Sin[θ])/(k r) == 0

Answer 1

There was nothing wrong with Mathematica's result. You just made a mistake in the time integration by enforcing a condition of vanishing magnetic field at the lower integration limit $t=0$ which is not correct. Instead, you should just do the indefinite integral, as follows:

Clear[ω, k, t, A, r, θ, ϕ]
E0 = {0, 0, (A Sin[θ])/r (Cos[k r - ω t] - Sin[k r - ω t]/(k r))};

curlE0 = Curl[E0, {r, θ, ϕ}, "Spherical"]
(*
==> {(
 2 A Cos[θ] (Cos[k r - t ω] - Sin[k r - t ω]/(k r)))/r^2, -
  ((A Sin[θ] (-(Cos[k r - t ω]/r) - 
     k Sin[k r - t ω] + Sin[k r - t ω]/(k r^2)))/r), 0}
*)

dtE0 = D[E0, t]
(*
==> {0, 0, (A Sin[θ] ((ω Cos[k r - t ω])/
  (k r) + ω Sin[k r - t ω]))/r}
*)

b = Integrate[curlE0, t] // Simplify
(*
==> {-((
  2 A Cos[θ] (Cos[k r - t ω] + 
     k r Sin[k r - t ω]))/(k r^3 ω)), (
 A Sin[θ] ((-1 + k^2 r^2) Cos[k r - t ω] - 
    k r Sin[k r - t ω]))/(k r^3 ω), 0}
*)

curlB = Simplify[Curl[b, {r, θ, ϕ}, "Spherical"]]
(*
==> {0, 0, -((
  A k Sin[θ] (Cos[k r - t ω] + 
     k r Sin[k r - t ω]))/(r^2 ω))}
*)

Simplify[dtE0 == -(ω/k)^2 curlB]

(* ==> True *)

I made several other modifications. First, get rid of the Subscript, then don't use E as a name.

Also, I avoided the second time integral by instead comparing the curl of the magnetic field to the time derivative of the given electric field. You also had a missing minus sign in the last comparison.