1
$\begingroup$

I am trying to numerically find an equilibrium (maximum) of a function using its differential. The following is a simplified version.

myEquilibrium[p_]:=Last[{myPreviousStep=1;NDSolve[{s'[t]==p-s[t],s[0]==myPreviousStep,WhenEvent[s[t]-myPreviousStep<10^-4||s[t]<10^-4,"StopIntegration"]},{s},{t,0,Infinity},StepMonitor:>(myPreviousStep=s[t])];myPreviousStep}]

myEquilibrium[.5] // 0.5 which is correct

The function should be constrained to positive s, which is why I included the s[t]<10^-4 requirement. However this does not seem to work.

myEquilibrium[-.5] // -0.5 but should be 10^-4

The NDSolve should also not go to 0 exactly, as the real, non-simplified version contains a 1/s[t] in the differential. That's another reason I want the procedure to stop at s[t]=10^-4, before s[t]=0.

myEquilibrium[0] // 0. but should be 10^-4

Finally, I often get NDSolve::mxst: Maximum number of 10000 steps reached at the point t == 6.57563031118913721074693815431*^4952. >> and NDSolve::ndsz: At t == 1.79769313486*^308, step size is effectively zero; singularity or stiff system suspected. >>. What would typically solve this issue?

Thanks.

Improve this question
$\endgroup$

1 Answer 1

Reset to default
2
$\begingroup$

Because s[t] is decreasing whenever p < 1, s[t] - myPreviousStep < 10^-4 will always be True. WhenEvent[cond, action] evaluates action when the condition changes from False to True; however, the condition is always True when p < 1. You need something like Abs[s[t] - myPreviousStep] < 10^-4, instead. Note that if p is closer to 1 than 10^-4, then the same thing happens. Also note this condition controls the accuracy in an indirect way, dependent on the convergence rate of NDSolve on your particular ODE.)

myEquilibrium[p_] := 
 Last[{myPreviousStep = 1; 
   NDSolve[{s'[t] == p - s[t], s[0] == myPreviousStep,
      WhenEvent[s[t] < 10^-4 || Abs[s[t] - myPreviousStep] < 10^-4, 
       "StopIntegration"]}, {s}, {t, 0, Infinity}, 
     StepMonitor :> (myPreviousStep = s[t])]; myPreviousStep}]

If you want to handle initial values p that happen to land close to an equilibrium position, then the following forces the condition to be False on the second step. The function step redefines itself after the first step. The first definition forces the condition Abs[s[t] - myPreviousStep] < 10^-4 to be False.

SetAttributes[step, HoldFirst];
myEquilibrium[p_] := Last[{
   step[var_, s_] := (var = s + 2. 10^-4; 
     step[var2_, s2_] := var2 = s2;); myPreviousStep = 1; 
   NDSolve[{s'[t] == p - s[t], s[0] == myPreviousStep,
     WhenEvent[s[t] < 10^-4 || Abs[s[t] - myPreviousStep] < 10^-4, 
      "StopIntegration"]}, {s}, {t, 0, Infinity}, 
    StepMonitor :> step[myPreviousStep, s[t]]]; myPreviousStep}]
Improve this answer
$\endgroup$
4
  • $\begingroup$ Thanks again Michael. The Abs I just forgot to add, but it makes all the difference. If I understand correctly, the second part of your answer explain how to change the order in which Mathematica 'updates' values, such that certain conditions are met one step earlier than otherwise. Is that correct? $\endgroup$
    – LBogaardt
    Jul 25, 2014 at 11:39
  • $\begingroup$ Seems to work very well for the full version too. I still get 'NDSolve::evcvmit: Event location failed to converge to the requested accuracy or precision within 100 iterations between t = 51.8086163110953 and t = 53.5515089038894. >>' for a short range of values of the parameters. $\endgroup$
    – LBogaardt
    Jul 25, 2014 at 11:55
  • $\begingroup$ @LBogaardt The second method works on myEquilibrium[1 - 0.00001], which may not be important in your use-case. At the first step taken by NDSolve, the step function gives myPreviousStep a bogus value constructed to make the WhenEvent condition be False. On subsequent steps, it is equivalent to myPreviousStep = s[t]. It ensures that the condition in WhenEvent is False for at least one step taken by NDSolve. It's an ad hoc solution, which may not be bulletproof in general although it seems like it would work for equilibria where s'[t] is proportional to p - s[t]. $\endgroup$
    – Michael E2
    Jul 25, 2014 at 12:19
  • $\begingroup$ @LBogaardt NDSolve::evcvmit can happen if the coefficient of p - s[t] is very small or p - s[t] is raised to a high power. For example, s'[t] == 10^-6 (p - s[t]) or s'[t] == (p - s[t])^3. There are probably other types of difficulties, too. WhenEvent has a "LocationMethod" option, which might be of interest. $\endgroup$
    – Michael E2
    Jul 25, 2014 at 12:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.